Merge branch 'tvheadend'

* tvheadend:
  media-tv/tvheadend: Fix IMDb URL, bug #536072
  media-tv/tvheadend: Version bump, bug #572576
  media-tv/tvheadend: Convert to git-r3.eclass
  media-tv/tvheadend: Disable building bundled libraries
  media-tv/tvheadend: Forward port additional USE flags
  media-tv/tvheadend: Forward port the libav USE flag
  media-tv/tvheadend: Update dependency syntax of live ebuild
  media-tv/tvheadend: Lower openssl dependency restriction
  media-tv/tvheadend: Move headers to being DEPEND-only
  media-tv/tvheadend: Move xmltv to being RDEPEND-only
  media-tv/tvheadend: Fixup DEPEND setting
  media-tv/tvheadend: Remove curl dependency
  media-tv/tvheadend: Remove epoll USE flag
  media-tv/tvheadend: Remove ccache USE flag
  media-tv/tvheadend: Remove iconv patch and USE flag
  media-tv/tvheadend: Remove --mandir configure option
  media-tv/tvheadend: Move dtv-scan-tables version to variable

6 files changed, 164 insertions, 68 deletions

diff --git a/media-tv/tvheadend/files/4.0.6-use-glibc-version-iconv.patch b/media-tv/tvheadend/files/4.0.6-use-glibc-version-iconv.patch
deleted file mode 100644
index 91187869a209..000000000000
--- a/media-tv/tvheadend/files/4.0.6-use-glibc-version-iconv.patch
+++ /dev/null
@@ -1,40 +0,0 @@
-From 984bcbb1acadd2957d7fc79dc4ec72e2e07a3572 Mon Sep 17 00:00:00 2001
-From: Olliver Schinagl <oliver@schinagl.nl>
-Date: Sat, 26 Sep 2015 22:36:08 +0200
-Subject: [PATCH] Use glibc version iconv
-
-Signed-off-by: Olliver Schinagl <oliver@schinagl.nl>
----
- Makefile  | 2 +-
- configure | 2 +-
- 2 files changed, 2 insertions(+), 2 deletions(-)
-
-diff --git a/Makefile b/Makefile
-index 07d6965..0ec0259 100644
---- a/Makefile
-+++ b/Makefile
-@@ -39,7 +39,7 @@ else
- LDFLAGS += -ldl -lpthread -lm
- endif
- ifeq ($(CONFIG_LIBICONV),yes)
--LDFLAGS += -liconv
-+LDFLAGS +=
- endif
- ifeq ($(PLATFORM), darwin)
- LDFLAGS += -framework CoreServices
-diff --git a/configure b/configure
-index 487456b..a6cce11 100755
---- a/configure
-+++ b/configure
-@@ -214,7 +214,7 @@ int test(void)
-   iconv_t ic = iconv_open("ASCII", "ASCII");
-   return 0;
- }
--' -liconv
-+'
- 
- if enabled_or_auto dvben50221; then
-   check_cc_snippet libdvben50221 '
--- 
-2.4.6
-
diff --git a/media-tv/tvheadend/metadata.xml b/media-tv/tvheadend/metadata.xml
index 154ca4bfa5de..c6e66a8cb613 100644
--- a/media-tv/tvheadend/metadata.xml
+++ b/media-tv/tvheadend/metadata.xml
@@ -11,13 +11,11 @@
 		<flag name="capmt">Enable support for capmt (dvbapi) protocol</flag>
 		<flag name="constcw">Enable support for the constcw protocol</flag>
 		<flag name="cwc">Enable support for the cwc (newcamd) protocol</flag>
-		<flag name="epoll">Enable epoll Linux system call</flag>
 		<flag name="hdhomerun">Enable support for the HDHomeRun device</flag>
 		<flag name="iptv">Enable support for Internet Protocol TV</flag>
 		<flag name="satip">Enable support for IP-based Satellite TV</flag>
 		<flag name="timeshift">Enable TimeShift support</flag>
 		<flag name="xmltv">Use <pkg>media-tv/xmltv</pkg></flag>
-		<flag name="ccache">Use <pkg>dev-util/ccache</pkg></flag>
 		<flag name="dvbscan">Use <pkg>media-tv/linuxtv-dvb-apps</pkg></flag>
 		<flag name="imagecache">Enable support for image caching</flag>
 		<flag name="uriparser">Use <pkg>dev-libs/uriparser</pkg></flag>
diff --git a/media-tv/tvheadend/tvheadend-3.4.27.ebuild b/media-tv/tvheadend/tvheadend-3.4.27.ebuild
index 0a8d85fee552..03f12f27b6ac 100644
--- a/media-tv/tvheadend/tvheadend-3.4.27.ebuild
+++ b/media-tv/tvheadend/tvheadend-3.4.27.ebuild
@@ -49,6 +49,10 @@ src_prepare() {
 
 	# remove '-Werror' wrt bug #438424
 	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
+
+	# imdb changed the search url, bug #536072
+	sed -e 's:akas.imdb.org:akas.imdb.com:' \
+		-i src/webui/static/app/epg.js || die 'sed failed!'
 }
 
 src_configure() {
diff --git a/media-tv/tvheadend/tvheadend-4.0.6.ebuild b/media-tv/tvheadend/tvheadend-4.0.6.ebuild
index ec2928533253..087ea471ce64 100644
--- a/media-tv/tvheadend/tvheadend-4.0.6.ebuild
+++ b/media-tv/tvheadend/tvheadend-4.0.6.ebuild
@@ -6,37 +6,39 @@ EAPI=5
 
 inherit eutils linux-info systemd toolchain-funcs user
 
+DTV_SCAN_TABLES_VERSION="2015-02-08-f2053b3"
+
 DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
 HOMEPAGE="https://tvheadend.org/"
 SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
-		dvbscan? ( http://linuxtv.org/downloads/dtv-scan-tables/dtv-scan-tables-2015-02-08-f2053b3.tar.bz2 )"
+		dvbscan? ( http://linuxtv.org/downloads/dtv-scan-tables/dtv-scan-tables-${DTV_SCAN_TABLES_VERSION}.tar.bz2 )"
 
 LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 
-IUSE="avahi ccache capmt constcw +cwc dbus +dvb +dvbscan epoll ffmpeg hdhomerun libav iconv imagecache inotify iptv satip +timeshift uriparser xmltv zlib"
+IUSE="avahi capmt constcw +cwc dbus +dvb +dvbscan ffmpeg hdhomerun libav imagecache inotify iptv satip +timeshift uriparser xmltv zlib"
 
 RDEPEND="dev-libs/openssl:=
+	virtual/libiconv
 	avahi? ( net-dns/avahi )
-	capmt? ( virtual/linuxtv-dvb-headers )
-	ccache? ( dev-util/ccache sys-libs/zlib )
 	dbus? ( sys-apps/dbus )
-	dvb? ( virtual/linuxtv-dvb-headers )
 	ffmpeg? (
 		!libav? ( media-video/ffmpeg:0= )
 		libav? ( media-video/libav:= )
 	)
 	hdhomerun? ( media-libs/libhdhomerun )
-	iconv? ( virtual/libiconv )
-	imagecache? ( net-misc/curl )
 	uriparser? ( dev-libs/uriparser )
-	zlib? ( sys-libs/zlib )
-	xmltv? ( media-tv/xmltv )"
+	zlib? ( sys-libs/zlib )"
 
-DEPEND="${DEPEND}
+DEPEND="${RDEPEND}
+	dvb? ( virtual/linuxtv-dvb-headers )
+	capmt? ( virtual/linuxtv-dvb-headers )
 	virtual/pkgconfig"
 
+RDEPEND+="
+	xmltv? ( media-tv/xmltv )"
+
 CONFIG_CHECK="~INOTIFY_USER"
 
 DOCS=( README.md )
@@ -47,7 +49,7 @@ src_unpack() {
 	if use dvbscan; then
 		mkdir "${S}/data/dvb-scan" || die
 		cd "${T}" || die
-		unpack dtv-scan-tables-2015-02-08-f2053b3.tar.bz2
+		unpack dtv-scan-tables-${DTV_SCAN_TABLES_VERSION}.tar.bz2
 		rmdir "${S}/data/dvb-scan" || die
 		mv "${T}/usr/share/dvb" "${S}/data/dvb-scan" || die
 
@@ -63,23 +65,19 @@ pkg_setup() {
 src_prepare() {
 	# remove '-Werror' wrt bug #438424
 	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
-	epatch "${FILESDIR}/${PV}-use-glibc-version-iconv.patch"
 }
 
 src_configure() {
 	econf --prefix="${EPREFIX}"/usr \
 		--datadir="${EPREFIX}"/usr/share \
-		--mandir="${EPREFIX}"/usr/share/man/man1 \
+		--disable-ccache \
 		$(use_enable avahi) \
-		$(use_enable ccache) \
 		$(use_enable capmt) \
 		$(use_enable constcw) \
 		$(use_enable cwc) \
 		$(use_enable dbus) \
 		$(use_enable dvb linuxdvb) \
 		$(use_enable dvbscan) \
-		$(use_enable epoll) \
-		--disable-kqueue \
 		$(use_enable ffmpeg libav) \
 		$(use_enable hdhomerun hdhomerun_client) \
 		$(use_enable imagecache) \
diff --git a/media-tv/tvheadend/tvheadend-4.0.8.ebuild b/media-tv/tvheadend/tvheadend-4.0.8.ebuild
new file mode 100644
index 000000000000..087ea471ce64
--- /dev/null
+++ b/media-tv/tvheadend/tvheadend-4.0.8.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils linux-info systemd toolchain-funcs user
+
+DTV_SCAN_TABLES_VERSION="2015-02-08-f2053b3"
+
+DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
+HOMEPAGE="https://tvheadend.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+		dvbscan? ( http://linuxtv.org/downloads/dtv-scan-tables/dtv-scan-tables-${DTV_SCAN_TABLES_VERSION}.tar.bz2 )"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="avahi capmt constcw +cwc dbus +dvb +dvbscan ffmpeg hdhomerun libav imagecache inotify iptv satip +timeshift uriparser xmltv zlib"
+
+RDEPEND="dev-libs/openssl:=
+	virtual/libiconv
+	avahi? ( net-dns/avahi )
+	dbus? ( sys-apps/dbus )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:0= )
+		libav? ( media-video/libav:= )
+	)
+	hdhomerun? ( media-libs/libhdhomerun )
+	uriparser? ( dev-libs/uriparser )
+	zlib? ( sys-libs/zlib )"
+
+DEPEND="${RDEPEND}
+	dvb? ( virtual/linuxtv-dvb-headers )
+	capmt? ( virtual/linuxtv-dvb-headers )
+	virtual/pkgconfig"
+
+RDEPEND+="
+	xmltv? ( media-tv/xmltv )"
+
+CONFIG_CHECK="~INOTIFY_USER"
+
+DOCS=( README.md )
+
+src_unpack() {
+	unpack "${P}.tar.gz"
+
+	if use dvbscan; then
+		mkdir "${S}/data/dvb-scan" || die
+		cd "${T}" || die
+		unpack dtv-scan-tables-${DTV_SCAN_TABLES_VERSION}.tar.bz2
+		rmdir "${S}/data/dvb-scan" || die
+		mv "${T}/usr/share/dvb" "${S}/data/dvb-scan" || die
+
+		# This is needed to prevent make from removing files
+		touch "${S}/data/dvb-scan/.stamp" || die
+	fi
+}
+
+pkg_setup() {
+	enewuser tvheadend -1 -1 /dev/null video
+}
+
+src_prepare() {
+	# remove '-Werror' wrt bug #438424
+	sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
+}
+
+src_configure() {
+	econf --prefix="${EPREFIX}"/usr \
+		--datadir="${EPREFIX}"/usr/share \
+		--disable-ccache \
+		$(use_enable avahi) \
+		$(use_enable capmt) \
+		$(use_enable constcw) \
+		$(use_enable cwc) \
+		$(use_enable dbus) \
+		$(use_enable dvb linuxdvb) \
+		$(use_enable dvbscan) \
+		$(use_enable ffmpeg libav) \
+		$(use_enable hdhomerun hdhomerun_client) \
+		$(use_enable imagecache) \
+		$(use_enable inotify) \
+		$(use_enable iptv) \
+		$(use_enable satip satip_server) \
+		$(use_enable satip satip_client) \
+		$(use_enable timeshift) \
+		$(use_enable uriparser) \
+		$(use_enable zlib)
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}/tvheadend.initd" tvheadend
+	newconfd "${FILESDIR}/tvheadend.confd" tvheadend
+
+	systemd_dounit "${FILESDIR}/tvheadend.service"
+
+	dodir /etc/tvheadend
+	fperms 0700 /etc/tvheadend
+	fowners tvheadend:video /etc/tvheadend
+}
+
+pkg_postinst() {
+	elog "The Tvheadend web interface can be reached at:"
+	elog "http://localhost:9981/"
+	elog
+	elog "Make sure that you change the default username"
+	elog "and password via the Configuration / Access control"
+	elog "tab in the web interface."
+}
diff --git a/media-tv/tvheadend/tvheadend-9999.ebuild b/media-tv/tvheadend/tvheadend-9999.ebuild
index 495a3d139734..731463da2f41 100644
--- a/media-tv/tvheadend/tvheadend-9999.ebuild
+++ b/media-tv/tvheadend/tvheadend-9999.ebuild
@@ -4,7 +4,7 @@
 
 EAPI=5
 
-inherit eutils git-2 linux-info systemd toolchain-funcs user
+inherit eutils git-r3 linux-info systemd toolchain-funcs user
 
 DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
 HOMEPAGE="https://tvheadend.org/"
@@ -14,18 +14,26 @@ LICENSE="GPL-3"
 SLOT="0"
 KEYWORDS=""
 
-IUSE="avahi ccache +dvb +dvbscan ffmpeg imagecache inotify uriparser xmltv zlib"
+IUSE="avahi capmt constcw +cwc dbus +dvb +dvbscan ffmpeg hdhomerun libav imagecache inotify iptv satip +timeshift uriparser xmltv zlib"
 
-DEPEND="dev-libs/openssl:0=
+RDEPEND="dev-libs/openssl:=
+	virtual/libiconv
 	avahi? ( net-dns/avahi )
-	ccache? ( dev-util/ccache )
-	dvb? ( virtual/linuxtv-dvb-headers )
-	ffmpeg? ( virtual/ffmpeg )
+	dbus? ( sys-apps/dbus )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:0= )
+		libav? ( media-video/libav:= )
+	)
+	hdhomerun? ( media-libs/libhdhomerun )
 	uriparser? ( dev-libs/uriparser )
-	zlib? ( sys-libs/zlib )
+	zlib? ( sys-libs/zlib )"
+
+DEPEND="${RDEPEND}
+	dvb? ( virtual/linuxtv-dvb-headers )
+	capmt? ( virtual/linuxtv-dvb-headers )
 	virtual/pkgconfig"
 
-RDEPEND="${DEPEND}
+RDEPEND+="
 	dvbscan? ( media-tv/linuxtv-dvb-apps )
 	xmltv? ( media-tv/xmltv )"
 
@@ -45,13 +53,24 @@ src_prepare() {
 src_configure() {
 	econf --prefix="${EPREFIX}"/usr \
 		--datadir="${EPREFIX}"/usr/share \
-		$(use_enable avahi) \
-		$(use_enable ccache) \
+		--disable-hdhomerun_static \
+		--disable-libffmpeg_static \
+		--disable-ccache \
 		--disable-dvbscan \
+		$(use_enable avahi) \
+		$(use_enable capmt) \
+		$(use_enable constcw) \
+		$(use_enable cwc) \
+		$(use_enable dbus) \
 		$(use_enable dvb linuxdvb) \
 		$(use_enable ffmpeg libav) \
+		$(use_enable hdhomerun hdhomerun_client) \
 		$(use_enable imagecache) \
 		$(use_enable inotify) \
+		$(use_enable iptv) \
+		$(use_enable satip satip_server) \
+		$(use_enable satip satip_client) \
+		$(use_enable timeshift) \
 		$(use_enable uriparser) \
 		$(use_enable zlib)
 }