1 files changed, 63 insertions, 0 deletions
diff --git a/x11-wm/i3/i3-4.1.ebuild b/x11-wm/i3/i3-4.1.ebuild
new file mode 100644
index 0000000..7e995c1
--- /dev/null
+++ b/x11-wm/i3/i3-4.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="3"
+
+inherit multilib
+
+DESCRIPTION="An improved dynamic tiling window manager"
+HOMEPAGE="http://i3wm.org/"
+SRC_URI="http://i3wm.org/downloads/${P}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="debug doc"
+
+RDEPEND="
+	dev-libs/libev
+	dev-libs/yajl
+	x11-libs/libX11
+	>=x11-libs/libxcb-1.1.93
+	x11-libs/startup-notification
+	>=x11-libs/xcb-util-0.3.3
+	|| (
+		<x11-libs/xcb-util-0.3.8
+		(
+			>=x11-libs/xcb-util-0.3.8
+			>=x11-libs/xcb-util-keysyms-0.3.8
+			>=x11-libs/xcb-util-wm-0.3.8
+		)
+	)
+	"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	sys-devel/bison
+	sys-devel/flex
+	>=x11-proto/xcb-proto-1.3
+	doc? ( >=app-text/asciidoc-8.3 )
+	"
+
+src_prepare() {
+	use debug || { sed -i -e "s:DEBUG=1:DEBUG=0:" common.mk || die "sed die - debug" ; }
+}
+
+src_compile() {
+	emake i3 || die "emake compile die"
+
+	local subs=( ${PN}-{input,msg} )
+
+	use doc && subs+=( docs )
+
+	for sub in ${subs[@]}; do
+		emake -C ${sub} || die "emake ${sub}"
+	done
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install die"
+	doman man/*.1 i3bar/doc/*.1 || die "doman die"
+	dodoc GOALS || die "dodoc die"
+	use doc && { dohtml -r docs/*.html || die "dohtml die" ; }
+}