blob: d21b3398c097dc662306121a889ed6230391c11e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit eutils user systemd
MY_PN="${PN/-bin}"
PERL_VER="5.24"
if [[ ${PV} == *_pre* ]] ; then
HASHID="fd6f4e3"
BUILDID="1499900819"
MY_PV="${PV/_pre*}"
SRC_URI="http://downloads.slimdevices.com/nightly/7.9/sc/${HASHID}/${MY_PN}-${MY_PV}-${BUILDID}.tgz"
S="${WORKDIR}/${MY_PN}-${MY_PV}-${BUILDID}"
KEYWORDS="~amd64"
elif [[ ${PV} == "9999" ]] ; then
EGIT_BRANCH="public/7.9"
EGIT_REPO_URI="https://github.com/Logitech/slimserver.git"
S="${WORKDIR}/slimserver"
inherit git-3
else
SRC_URI="http://downloads.slimdevices.com/LogitechMediaServer_v${PV}/${MY_PN}-${PV}.tgz"
S="${WORKDIR}/${MY_PN}-${PV}"
KEYWORDS="~amd64"
fi
DESCRIPTION="Logitech Media Server (streaming audio server)"
HOMEPAGE="http://github.com/Logitech/slimserver"
LICENSE="${PN}"
RESTRICT="bindist mirror"
SLOT="0"
IUSE=""
# Installation dependencies.
DEPEND="
!media-sound/squeezecenter
!media-sound/squeezeboxserver
app-arch/unzip
"
# Runtime dependencies.
RDEPEND="
!prefix? ( >=sys-apps/baselayout-2.0.0 )
!prefix? ( virtual/logger )
app-admin/logrotate
=dev-lang/perl-${PERL_VER}*[ithreads]
>=dev-perl/Data-UUID-1.202
"
QA_PREBUILT="
opt/logitechmediaserver/Bin/x86_64-linux/*
opt/logitechmediaserver/CPAN/arch/${PERL_VER}/x86_64-linux-thread-multi/*
"
RUN_UID=logitechmediaserver
RUN_GID=logitechmediaserver
# Installation locations
OPTDIR="/opt/${MY_PN}"
VARDIR="/var/lib/${MY_PN}"
CACHEDIR="${VARDIR}/cache"
USRPLUGINSDIR="${VARDIR}/Plugins"
SVRPLUGINSDIR="${CACHEDIR}/InstalledPlugins"
CLIENTPLAYLISTSDIR="${VARDIR}/ClientPlaylists"
PREFSDIR="/etc/${MY_PN}"
LOGDIR="/var/log/${MY_PN}"
SVRPREFS="${PREFSDIR}/server.prefs"
# Old Squeezebox Server file locations
SBS_PREFSDIR='/etc/squeezeboxserver/prefs'
SBS_SVRPREFS="${SBS_PREFSDIR}/server.prefs"
SBS_VARLIBDIR='/var/lib/squeezeboxserver'
SBS_SVRPLUGINSDIR="${SBS_VARLIBDIR}/cache/InstalledPlugins"
SBS_USRPLUGINSDIR="${SBS_VARLIBDIR}/Plugins"
DOCS="Changelog?.html Installation.txt"
pkg_setup() {
enewgroup ${RUN_GID}
enewuser ${RUN_UID} -1 -1 "/dev/null" ${RUN_GID}
}
src_prepare() {
epatch "${FILESDIR}/${P}-uuid-gentoo.patch"
epatch "${FILESDIR}/${P}-client-playlists-gentoo.patch"
(cd CPAN/arch && rm -rf 5.10 5.12 5.14 5.16 5.18 5.20 5.22 5.8)
(cd CPAN/arch/${PERL_VER} && rm -rf arm-linux* i386-linux*)
(cd Bin && rm -rf arm*-linux i86pc-solaris* sparc-linux i386-linux powerpc-linux)
eapply_user
}
src_install() {
# The custom OS module for Gentoo - provides OS-specific path details
cp "${FILESDIR}/gentoo-filepaths.pm" "Slim/Utils/OS/Custom.pm" || die "Unable to install Gentoo custom OS module"
# Everthing into our package in the /opt hierarchy (LHS)
dodir "${OPTDIR}"
cp -aR "${S}"/* "${ED}${OPTDIR}" || die "Unable to install package files"
dodoc ${DOCS}
dodoc "${FILESDIR}/Gentoo-plugins-README.txt"
dodoc "${FILESDIR}/Gentoo-detailed-changelog.txt"
# Preferences directory
dodir "${PREFSDIR}"
fowners ${RUN_UID}:${RUN_GID} "${PREFSDIR}"
fperms 770 "${PREFSDIR}"
# Install init scripts (OpenRC)
newconfd "${FILESDIR}/logitechmediaserver.conf.d" "${MY_PN}"
newinitd "${FILESDIR}/logitechmediaserver.init.d" "${MY_PN}"
# Install unit file (systemd)
systemd_dounit "${FILESDIR}/${MY_PN}.service"
# Initialize server cache directory
dodir "${CACHEDIR}"
fowners ${RUN_UID}:${RUN_GID} "${CACHEDIR}"
fperms 770 "${CACHEDIR}"
# Initialize the log directory
dodir "${LOGDIR}"
fowners ${RUN_UID}:${RUN_GID} "${LOGDIR}"
fperms 770 "${LOGDIR}"
touch "${ED}/${LOGDIR}/server.log"
touch "${ED}/${LOGDIR}/scanner.log"
touch "${ED}/${LOGDIR}/perfmon.log"
fowners ${RUN_UID}:${RUN_GID} "${LOGDIR}/server.log"
fowners ${RUN_UID}:${RUN_GID} "${LOGDIR}/scanner.log"
fowners ${RUN_UID}:${RUN_GID} "${LOGDIR}/perfmon.log"
# Initialise the user-installed plugins directory
dodir "${USRPLUGINSDIR}"
fowners ${RUN_UID}:${RUN_GID} "${USRPLUGINSDIR}"
fperms 770 "${USRPLUGINSDIR}"
# Initialise the client playlists directory
dodir "${CLIENTPLAYLISTSDIR}"
fowners ${RUN_UID}:${RUN_GID} "${CLIENTPLAYLISTSDIR}"
fperms 770 "${CLIENTPLAYLISTSDIR}"
# Install logrotate support
insinto /etc/logrotate.d
newins "${FILESDIR}/logitechmediaserver.logrotate.d" "${MY_PN}"
}
lms_starting_instr() {
elog "Logitech Media Server can be started with the following command (OpenRC):"
elog "\t/etc/init.d/logitechmediaserver start"
elog "or (systemd):"
elog "\tsystemctl start logitechmediaserver"
elog ""
elog "Logitech Media Server can be automatically started on each boot"
elog "with the following command (OpenRC):"
elog "\trc-update add logitechmediaserver default"
elog "or (systemd):"
elog "\tsystemctl enable logitechmediaserver"
elog ""
elog "You might want to examine and modify the following configuration"
elog "file before starting Logitech Media Server:"
elog "\t/etc/conf.d/logitechmediaserver"
elog ""
# Discover the port number from the preferences, but if it isn't there
# then report the standard one.
httpport=$(gawk '$1 == "httpport:" { print $2 }' "${ROOT}${SVRPREFS}" 2>/dev/null)
elog "You may access and configure Logitech Media Server by browsing to:"
elog "\thttp://localhost:${httpport:-9000}/"
elog ""
}
pkg_postinst() {
# Point user to database configuration step, if an old installation
# of SBS is found.
if [ -f "${SBS_SVRPREFS}" ]; then
elog "If this is a new installation of Logitech Media Server and you"
elog "previously used Squeezebox Server (media-sound/squeezeboxserver)"
elog "then you may migrate your previous preferences and plugins by"
elog "running the following command (note that this will overwrite any"
elog "current preferences and plugins):"
elog "\temerge --config =${CATEGORY}/${PF}"
elog ""
fi
# Tell use user where they should put any manually-installed plugins.
elog "Manually installed plugins should be placed in the following"
elog "directory:"
elog "\t${USRPLUGINSDIR}"
elog ""
# Show some instructions on starting and accessing the server.
lms_starting_instr
elog "Support thread at: http://forums.slimdevices.com/showthread.php?107110-Logitech-Media-Server-7-9-is-out!"
}
lms_remove_db_prefs() {
MY_PREFS=$1
einfo "Correcting database connection configuration:"
einfo "\t${MY_PREFS}"
TMPPREFS="${T}"/lmsserver-prefs-$$
touch "${EROOT}${MY_PREFS}"
sed -e '/^dbusername:/d' -e '/^dbpassword:/d' -e '/^dbsource:/d' < "${EROOT}${MY_PREFS}" > "${TMPPREFS}"
mv "${TMPPREFS}" "${EROOT}${MY_PREFS}"
chown ${RUN_UID}:${RUN_GID} "${EROOT}${MY_PREFS}"
chmod 660 "${EROOT}${MY_PREFS}"
}
pkg_config() {
einfo "Press ENTER to migrate any preferences from a previous installation of"
einfo "Squeezebox Server (media-sound/squeezeboxserver) to this installation"
einfo "of Logitech Media Server."
einfo ""
einfo "Note that this will remove any current preferences and plugins and"
einfo "therefore you should take a backup if you wish to preseve any files"
einfo "from this current Logitech Media Server installation."
einfo ""
einfo "Alternatively, press Control-C to abort now..."
read
# Preferences.
einfo "Migrating previous Squeezebox Server configuration:"
if [ -f "${SBS_SVRPREFS}" ]; then
[ -d "${EROOT}${PREFSDIR}" ] && rm -rf "${EROOT}${PREFSDIR}"
einfo "\tPreferences (${SBS_PREFSDIR})"
cp -r "${EROOT}${SBS_PREFSDIR}" "${EROOT}${PREFSDIR}"
chown -R ${RUN_UID}:${RUN_GID} "${EROOT}${PREFSDIR}"
chmod -R u+w,g+w "${EROOT}${PREFSDIR}"
chmod 770 "${EROOT}${PREFSDIR}"
fi
# Plugins installed through the built-in extension manager.
if [ -d "${EROOT}${SBS_SVRPLUGINSDIR}" ]; then
einfo "\tServer plugins (${SBS_SVRPLUGINSDIR})"
[ -d "${EROOT}${SVRPLUGINSDIR}" ] && rm -rf "${EROOT}${SVRPLUGINSDIR}"
cp -r "${EROOT}${SBS_SVRPLUGINSDIR}" "${EROOT}${SVRPLUGINSDIR}"
chown -R ${RUN_UID}:${RUN_GID} "${EROOT}${SVRPLUGINSDIR}"
chmod -R u+w,g+w "${EROOT}${SVRPLUGINSDIR}"
chmod 770 "${EROOT}${SVRPLUGINSDIR}"
fi
# Plugins manually installed by the user.
if [ -d "${EROOT}${SBS_USRPLUGINSDIR}" ]; then
einfo "\tUser plugins (${SBS_USRPLUGINSDIR})"
[ -d "${EROOT}${USRPLUGINSDIR}" ] && rm -rf "${EROOT}${USRPLUGINSDIR}"
cp -r "${EROOT}${SBS_USRPLUGINSDIR}" "${EROOT}${USRPLUGINSDIR}"
chown -R ${RUN_UID}:${RUN_GID} "${EROOT}${USRPLUGINSDIR}"
chmod -R u+w,g+w "${EROOT}${USRPLUGINSDIR}"
chmod 770 "${EROOT}${USRPLUGINSDIR}"
fi
# Remove the existing MySQL preferences from Squeezebox Server (if any).
lms_remove_db_prefs "${SVRPREFS}"
# Phew - all done. Give some tips on what to do now.
einfo "Done."
einfo ""
}
|
GitWeb