blob: fec9318f2815affd6984a317431749bd99684de6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
|
# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="https://gitlab.freedesktop.org/xorg/xserver.git"
inherit git-r3
else
SRC_URI="https://xorg.freedesktop.org/archive/individual/xserver/${P}.tar.xz"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
fi
DESCRIPTION="Standalone X server running under Wayland"
HOMEPAGE="https://wayland.freedesktop.org/xserver.html"
LICENSE="MIT"
SLOT="0"
IUSE="libei selinux systemd video_cards_nvidia unwind xcsecurity"
COMMON_DEPEND="
dev-libs/libbsd
dev-libs/openssl:=
>=dev-libs/wayland-1.21.0
>=dev-libs/wayland-protocols-1.30
media-fonts/font-util
>=media-libs/libepoxy-1.5.4[X,egl(+)]
media-libs/libglvnd[X]
>=media-libs/mesa-21.1[X(+),egl(+),gbm(+)]
>=x11-libs/libdrm-2.4.109
>=x11-libs/libXau-1.0.4
x11-libs/libxcvt
>=x11-libs/libXdmcp-1.0.2
>=x11-libs/libXfont2-2.0.1
x11-libs/libxkbfile
>=x11-libs/libxshmfence-1.1
>=x11-libs/pixman-0.27.2
>=x11-misc/xkeyboard-config-2.4.1-r3
libei? ( dev-libs/libei )
systemd? ( sys-apps/systemd )
unwind? ( sys-libs/libunwind )
video_cards_nvidia? ( gui-libs/egl-wayland )
"
DEPEND="
${COMMON_DEPEND}
>=x11-base/xorg-proto-2023.2
>=x11-libs/xtrans-1.3.5
"
RDEPEND="
${COMMON_DEPEND}
x11-apps/xkbcomp
libei? ( >=sys-apps/xdg-desktop-portal-1.18.0 )
selinux? ( sec-policy/selinux-xserver )
"
BDEPEND="
app-alternatives/lex
dev-util/wayland-scanner
"
PATCHES=(
"${FILESDIR}"/${PN}-drop-redundantly-installed-files.patch
"${FILESDIR}"/${PN}-23.2.3-systemd-automagic.patch
"${FILESDIR}"/${PN}-23.3.6-test-Skip-Xwayland-test-early-if-PIGLIT_DIR-XTEST_DI.patch
)
src_configure() {
local emesonargs=(
$(meson_use selinux xselinux)
$(meson_use systemd)
$(meson_use unwind libunwind)
$(meson_use xcsecurity)
$(meson_use video_cards_nvidia xwayland_eglstream)
-Ddpms=true
-Ddri3=true
-Ddrm=true
-Ddtrace=false
-Dglamor=true
-Dglx=true
-Dipv6=true
-Dsecure-rpc=false
-Dscreensaver=true
-Dsha1=libcrypto
-Dxace=true
-Dxdmcp=true
-Dxinerama=true
-Dxvfb=true
-Dxv=true
-Dxwayland-path="${EPREFIX}"/usr/bin
-Dlibdecor=false
-Ddocs=false
-Ddevel-docs=false
-Ddocs-pdf=false
)
if use libei; then
emesonargs+=( -Dxwayland_ei=portal )
else
emesonargs+=( -Dxwayland_ei=false )
fi
meson_src_configure
}
src_install() {
dosym ../bin/Xwayland /usr/libexec/Xwayland
meson_src_install
}
|
GitWeb