blob: fc9ce8107b274c7f66f27d81b29565315ddb73f9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic toolchain-funcs
DESCRIPTION="tools to create and extract Squashfs filesystems"
HOMEPAGE="https://github.com/plougher/squashfs-tools"
SRC_URI="${HOMEPAGE}/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86"
IUSE="debug lz4 lzma lzo static xattr +xz zstd"
LIB_DEPEND="
sys-libs/zlib[static-libs(+)]
!xz? ( !lzo? ( sys-libs/zlib[static-libs(+)] ) )
lz4? ( app-arch/lz4[static-libs(+)] )
lzma? ( app-arch/xz-utils[static-libs(+)] )
lzo? ( dev-libs/lzo[static-libs(+)] )
xattr? ( sys-apps/attr[static-libs(+)] )
xz? ( app-arch/xz-utils[static-libs(+)] )
zstd? ( app-arch/zstd[static-libs(+)] )
"
RDEPEND="
!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
"
DEPEND="
${RDEPEND}
static? ( ${LIB_DEPEND} )
"
S=${WORKDIR}/${P}/${PN}
use10() { usex $1 1 0 ; }
src_configure() {
# restore GNU89 inline semantics to
# emit function symbols, bug 595290
append-cflags -std=gnu89
# set up make command line variables in EMAKE_SQUASHFS_CONF
EMAKE_SQUASHFS_CONF=(
LZMA_XZ_SUPPORT=$(use10 lzma)
LZO_SUPPORT=$(use10 lzo)
LZ4_SUPPORT=$(use10 lz4)
XATTR_SUPPORT=$(use10 xattr)
XZ_SUPPORT=$(use10 xz)
ZSTD_SUPPORT=$(use10 zstd)
)
tc-export CC
use debug && append-cppflags -DSQUASHFS_TRACE
use static && append-ldflags -static
}
src_compile() {
emake "${EMAKE_SQUASHFS_CONF[@]}"
}
src_install() {
dobin mksquashfs unsquashfs
cd ..
dodoc ACKNOWLEDGEMENTS CHANGES README*
dodoc -r RELEASE-READMEs
}
|
GitWeb
