blob: 5438b3b45f4109d82a601cac2705dc9cb2bbcc62 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_P="${P/resource-}"
inherit autotools
DESCRIPTION="Resources pack for Heartbeat / Pacemaker"
HOMEPAGE="http://www.linux-ha.org/wiki/Resource_Agents"
SRC_URI="https://github.com/ClusterLabs/resource-agents/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~hppa x86"
IUSE="doc libnet rgmanager systemd"
RDEPEND="
sys-apps/iproute2
>=sys-cluster/cluster-glue-1.0.12-r1
libnet? ( net-libs/libnet:1.1 )
systemd? ( sys-apps/systemd )
"
DEPEND="${RDEPEND}"
BDEPEND="
doc? (
dev-libs/libxslt
app-text/docbook-xsl-stylesheets
)
"
PATCHES=(
"${FILESDIR}/4.6.1-configure.patch"
)
src_prepare() {
default
eautoreconf
}
src_configure() {
# --with-ocf-root needs to be /usr/lib, see bug #720420
econf \
--disable-fatal-warnings \
--localstatedir=/var \
--with-ocf-root=/usr/lib/ocf \
--with-rsctmpdir=/run/resource-agents \
$(use_enable doc) \
$(use_enable libnet)
}
src_install() {
default
rm -rf "${ED}/usr/lib/ocf/resource.d/redhat" || die
rm -rf "${ED}"/etc/init.d/ || die
rm -rf "${ED}"{,/var}/run || die
use rgmanager || rm -rf "${ED}"/usr/share/cluster/ "${ED}"/var/
}
pkg_postinst() {
elog "To use Resource Agents installed in ${EROOT}/usr/lib/ocf/resource.d"
elog "you have to emerge required runtime dependencies manually."
elog ""
elog "Description and dependencies of all Agents can be found on"
elog "http://www.linux-ha.org/wiki/Resource_Agents"
elog "or in the documentation of this package."
}
|
GitWeb
