sci-biology/last/last-299-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

PYTHON_COMPAT=( python2_7 )

inherit toolchain-funcs python-single-r1

DESCRIPTION="Genome-scale comparison of biological sequences"
HOMEPAGE="http://last.cbrc.jp/"
SRC_URI="http://last.cbrc.jp/${P}.zip"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="${PYTHON_DEPS}"
DEPEND="app-arch/unzip"

PATCHES=(
	"${FILESDIR}"/${PN}-299-fix-build-system.patch
	"${FILESDIR}"/${PN}-299-portable-shebangs.patch
)

src_configure() {
	tc-export CC CXX
}

src_install() {
	local DOCS=( doc/*.txt ChangeLog.txt README.txt )
	local HTML_DOCS=( doc/*html )
	einstalldocs

	dobin src/last{al,db,ex}

	cd scripts || die
	local i
	for i in *py; do
		newbin ${i} ${i%.py}
	done
	dobin *sh
}