blob: 114a6529ee8438f27e865292ed66f491d2cfca6f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit cmake
MY_P="LibVNCServer-${PV}"
DESCRIPTION="library for creating vnc servers"
HOMEPAGE="https://libvnc.github.io/"
SRC_URI="https://github.com/LibVNC/${PN}/archive/${MY_P}.tar.gz"
S="${WORKDIR}/${PN}-${MY_P}"
# libvncserver/tightvnc-filetransfer/*: GPL-2, but we don't build it
# common/d3des.*: https://github.com/LibVNC/libvncserver/issues/88
LICENSE="GPL-2+ LGPL-2.1+ BSD MIT"
# no sub slot wanted (yet), see #578958
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-linux ~x86-linux"
IUSE="+24bpp gcrypt gnutls ipv6 +jpeg libressl lzo +png sasl ssl systemd +threads +zlib"
# https://bugs.gentoo.org/690202
# https://bugs.gentoo.org/435326
# https://bugs.gentoo.org/550916
REQUIRED_USE="jpeg? ( zlib ) png? ( zlib ) ssl? ( !gnutls? ( threads ) )"
DEPEND="
gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0= )
ssl? (
!gnutls? (
!libressl? ( >=dev-libs/openssl-1.0.2:0= )
libressl? ( >=dev-libs/libressl-2.7.0:0= )
)
gnutls? ( >=net-libs/gnutls-2.12.23-r6:0= )
)
jpeg? ( >=virtual/jpeg-0-r2:0 )
lzo? ( dev-libs/lzo )
png? ( >=media-libs/libpng-1.6.10:0= )
sasl? ( dev-libs/cyrus-sasl )
systemd? ( sys-apps/systemd:= )
zlib? ( >=sys-libs/zlib-1.2.8-r1:0= )"
RDEPEND="${DEPEND}"
DOCS=( AUTHORS ChangeLog NEWS README.md TODO )
PATCHES=(
"${FILESDIR}"/${P}-cmake-libdir.patch
"${FILESDIR}"/${P}-pkgconfig-libdir.patch
"${FILESDIR}"/${P}-libgcrypt.patch
"${FILESDIR}"/${P}-sparc-unaligned.patch
"${FILESDIR}"/${P}-CVE-2018-20750.patch
"${FILESDIR}"/${P}-CVE-2019-15681.patch
"${FILESDIR}"/${P}-fix-tight-raw-decoding.patch
"${FILESDIR}"/${P}-fix-shutdown-crash.patch
)
src_configure() {
local mycmakeargs=(
-DWITH_ZLIB=$(usex zlib ON OFF)
-DWITH_LZO=$(usex lzo ON OFF)
-DWITH_JPEG=$(usex jpeg ON OFF)
-DWITH_PNG=$(usex png ON OFF)
-DWITH_THREADS=$(usex threads ON OFF)
-DWITH_GNUTLS=$(usex gnutls $(usex ssl ON OFF) OFF)
-DWITH_OPENSSL=$(usex gnutls OFF $(usex ssl ON OFF))
-DWITH_GCRYPT=$(usex gcrypt ON OFF)
-DWITH_SYSTEMD=$(usex systemd ON OFF)
-DWITH_FFMPEG=OFF
-DWITH_24BPP=$(usex 24bpp ON OFF)
-DWITH_IPv6=$(usex ipv6 ON OFF)
-DWITH_SASL=$(usex sasl ON OFF)
)
cmake_src_configure
}
|
GitWeb
