blob: 5752b46e6cdcdf17bac04d5b3d513e2c59b3bca4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="C library implementing the OAuth secure authentication protocol"
HOMEPAGE="http://liboauth.sourceforge.net/"
SRC_URI="mirror://sourceforge/project/${PN}/${P}.tar.gz"
LICENSE="|| ( GPL-2 MIT )"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 sparc x86 ~x64-macos"
IUSE="bindist curl doc libressl +nss"
REQUIRED_USE="bindist? ( nss )"
PATCHES=(
"${FILESDIR}"/${PN}-1.0.1-doxygen-out-of-tree.patch
"${FILESDIR}"/${PN}-1.0.3-openssl-1.1.patch
"${FILESDIR}"/${PN}-1.0.3-openssl-1.1_2.patch
)
CDEPEND="
curl? ( net-misc/curl )
nss? ( dev-libs/nss
curl? ( || (
net-misc/curl[ssl,curl_ssl_nss]
net-misc/curl[-ssl]
) )
)
!nss? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
curl? ( || (
net-misc/curl[ssl,curl_ssl_openssl]
net-misc/curl[-ssl]
) )
)
"
RDEPEND="${CDEPEND}"
DEPEND="
${CDEPEND}
doc? (
app-doc/doxygen
media-gfx/graphviz
media-fonts/freefont
)
"
BDEPEND="
virtual/pkgconfig
"
src_configure() {
local myeconfargs=(
--disable-static
$(use_enable !curl curl)
$(use_enable curl libcurl)
$(use_enable nss)
)
econf "${myeconfargs[@]}"
}
src_compile() {
default
if use doc ; then
# make sure fonts are found
export DOTFONTPATH="${EPREFIX}"/usr/share/fonts/freefont-ttf
emake dox
fi
}
DOCS=( AUTHORS ChangeLog LICENSE.OpenSSL README )
src_install() {
use doc && HTML_DOCS=( doc/html/. )
default
find "${ED}" -name "*.la" -delete || die
}
|
GitWeb