blob: 722dbc5dde2e5abcc09e560a91b00d39da3c184d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="A tool for network monitoring and data acquisition"
HOMEPAGE="https://www.tcpdump.org/ https://github.com/the-tcpdump-group/tcpdump"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/the-tcpdump-group/tcpdump"
else
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/tcpdump.asc
inherit verify-sig
# Note: drop -upstream on bump, this is just because we switched to the official
# distfiles for verify-sig
SRC_URI="https://www.tcpdump.org/release/${P}.tar.gz -> ${P}-upstream.tar.gz"
SRC_URI+=" verify-sig? ( https://www.tcpdump.org/release/${P}.tar.gz.sig -> ${P}-upstream.tar.gz.sig )"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
fi
LICENSE="BSD"
SLOT="0"
IUSE="+drop-root +smi +ssl +samba suid test"
REQUIRED_USE="test? ( samba )"
RESTRICT="!test? ( test )"
# Assorted failures: bug #768498
#RESTRICT="test"
RDEPEND="
net-libs/libpcap
drop-root? (
acct-group/pcap
acct-user/pcap
sys-libs/libcap-ng
)
smi? ( net-libs/libsmi )
ssl? (
>=dev-libs/openssl-0.9.6m:0=
)
suid? (
acct-group/pcap
acct-user/pcap
)
"
DEPEND="
${RDEPEND}
test? (
>=net-libs/libpcap-1.9.1
dev-lang/perl
)
"
BDEPEND="drop-root? ( virtual/pkgconfig )"
if [[ ${PV} != *9999* ]] ; then
BDEPEND+=" verify-sig? ( app-crypt/openpgp-keys-tcpdump )"
fi
PATCHES=(
"${FILESDIR}"/${PN}-9999-libdir.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
econf \
$(use_enable samba smb) \
$(use_with drop-root cap-ng) \
$(use_with drop-root chroot '') \
$(use_with smi) \
$(use_with ssl crypto "${ESYSROOT}/usr") \
$(usex drop-root "--with-user=pcap" "")
}
src_test() {
if [[ ${EUID} -ne 0 ]] || ! use drop-root ; then
emake check
else
ewarn "If you want to run the test suite, make sure you either"
ewarn "set FEATURES=userpriv or set USE=-drop-root"
fi
}
src_install() {
dosbin tcpdump
doman tcpdump.1
dodoc *.awk
dodoc CHANGES CREDITS README.md
if use suid ; then
fowners root:pcap /usr/sbin/tcpdump
fperms 4110 /usr/sbin/tcpdump
fi
}
pkg_postinst() {
use suid && elog "To let normal users run tcpdump, add them to the pcap group."
}
|
GitWeb