blob: 99c261c6b5ea03c4329a611486b82f1889f6f4a8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
PYTHON_REQ_USE="threads(+)"
inherit gnome.org gnome2-utils meson virtualx xdg python-single-r1
DESCRIPTION="Media player for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/Videos https://gitlab.gnome.org/GNOME/totem/"
LICENSE="GPL-2+ LGPL-2+"
SLOT="0"
IUSE="gtk-doc +python test"
# see bug #359379
REQUIRED_USE="
python? ( ${PYTHON_REQUIRED_USE} )
"
RESTRICT="!test? ( test )"
KEYWORDS="amd64 ~arm arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv x86"
COMMON_DEPEND="
>=dev-libs/glib-2.72.0:2
>=x11-libs/gtk+-3.22.0:3[introspection]
>=gui-libs/libhandy-1.5.0:1
>=media-libs/gstreamer-1.6.0:1.0
>=media-libs/gst-plugins-base-1.6.0:1.0[pango]
>=media-libs/gst-plugins-good-1.6.0:1.0
>=media-libs/grilo-0.3.0:0.3[playlist]
>=dev-libs/libpeas-1.1.0:0[gtk]
>=dev-libs/totem-pl-parser-3.26.5:0=[introspection]
gnome-base/gnome-desktop:3=
gnome-base/gsettings-desktop-schemas
>=x11-libs/cairo-1.14
x11-libs/gdk-pixbuf:2
>=dev-libs/gobject-introspection-1.54:=
python? (
${PYTHON_DEPS}
$(python_gen_cond_dep '
>=dev-python/pygobject-2.90.3:3[${PYTHON_USEDEP}]
')
)
"
RDEPEND="${COMMON_DEPEND}
media-plugins/grilo-plugins:0.3
media-plugins/gst-plugins-gtk:1.0[opengl]
media-plugins/gst-plugins-meta:1.0
media-plugins/gst-plugins-taglib:1.0
x11-themes/adwaita-icon-theme
dev-libs/libportal:0=[gtk]
python? (
x11-libs/pango[introspection]
>=dev-libs/libpeas-1.1.0:0[python,${PYTHON_SINGLE_USEDEP}]
$(python_gen_cond_dep '
dev-python/dbus-python[${PYTHON_USEDEP}]
')
)
"
DEPEND="${COMMON_DEPEND}
x11-base/xorg-proto
"
BDEPEND="
dev-lang/perl
gtk-doc? ( >=dev-util/gtk-doc-1.14
app-text/docbook-xml-dtd:4.5 )
dev-util/glib-utils
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
# perl for pod2man
# Prevent dev-python/pylint dep, bug #482538
PATCHES=(
"${FILESDIR}"/${PV}-gst-inspect-sandbox.patch # Allow disabling calls to gst-inspect (sandbox issue)
)
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
default
xdg_environment_reset
# Drop pointless samplepython plugin from build
sed -e '/samplepython/d' -i src/plugins/meson.build || die
}
src_configure() {
local emesonargs=(
-Dhelp=true
-Denable-easy-codec-installation=yes
-Denable-python=$(usex python yes no)
-Dlibportal=enabled
-Dwith-plugins=all # in 3.34.1 only builtin and python plugins are left, and python is extra controlled by enable-python
$(meson_use gtk-doc enable-gtk-doc)
-Dprofile=default
-Dinspector-page=false
-Dgst-inspect=false
)
meson_src_configure
}
src_install() {
local -x GST_PLUGIN_SYSTEM_PATH_1_0= # bug 812170
meson_src_install
if use python ; then
python_optimize "${ED}"/usr/$(get_libdir)/totem/plugins/
fi
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
src_test() {
virtx meson_src_test
}
|
GitWeb