blob: 8ab0e6d7ccd0b4c2a8faaeca46a627e896b2b232 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils multilib-minimal
DESCRIPTION="An optimised MPEG Audio Layer 2 (MP2) encoder"
HOMEPAGE="http://www.twolame.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ia64 ~mips ppc ~ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="static-libs"
RDEPEND=">=media-libs/libsndfile-1.0.25[${MULTILIB_USEDEP}]
abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r6
!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}
virtual/pkgconfig"
PATCHES=( "${FILESDIR}/${PV}-perl-tests.patch" )
src_prepare() {
sed -i -e '/CFLAGS/s:-O3::' configure || die
# remove -Werror, bug 493940
sed -i -e '/WARNING_CFLAGS/s:-Werror::' configure || die
if [[ ${CHOST} == *solaris* ]]; then
# libsndfile doesn't like -std=c99 on Solaris
sed -i -e '/CFLAGS/s:-std=c99::' configure || die
# configure isn't really bourne shell (comment 0) or dash (comment 6)
# compatible, bug #388885
export CONFIG_SHELL=${BASH}
fi
default
}
multilib_src_configure() {
ECONF_SOURCE=${S} \
econf $(use_enable static-libs static)
}
multilib_src_install_all() {
default
prune_libtool_files --all
}
|
GitWeb
