blob: 4137193881c6f7b2fe9b7aee3367491eb62d8a3c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..11} )
PVCUT=$(ver_cut 1-2)
QTMIN=5.15.4
inherit ecm frameworks.kde.org optfeature python-any-r1
DESCRIPTION="Library for extracting file metadata"
LICENSE="LGPL-2+"
KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86"
IUSE="epub exif ffmpeg mobi office pdf taglib"
RESTRICT="test"
BDEPEND="
test? ( ${PYTHON_DEPS} )
"
RDEPEND="
>=dev-qt/qtxml-${QTMIN}:5
=kde-frameworks/kcoreaddons-${PVCUT}*:5
=kde-frameworks/ki18n-${PVCUT}*:5
epub? ( app-text/ebook-tools )
exif? ( media-gfx/exiv2:= )
ffmpeg? ( media-video/ffmpeg:0= )
mobi? ( kde-apps/kdegraphics-mobipocket:5 )
office? ( =kde-frameworks/karchive-${PVCUT}*:5 )
pdf? ( app-text/poppler[qt5] )
taglib? ( media-libs/taglib )
"
DEPEND="${RDEPEND}
kernel_linux? ( sys-apps/attr )
"
pkg_setup() {
use test && python-any-r1_pkg_setup
ecm_pkg_setup
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package epub EPub)
$(cmake_use_find_package exif LibExiv2)
$(cmake_use_find_package ffmpeg FFmpeg)
$(cmake_use_find_package mobi QMobipocket)
$(cmake_use_find_package office KF5Archive)
$(cmake_use_find_package pdf Poppler)
$(cmake_use_find_package taglib Taglib)
)
ecm_src_configure
}
src_test() {
# FIXME: bug 644650, fails on tmpfs (but not for everyone)
local myctestargs=( -E "(usermetadatawritertest)" )
ecm_src_test
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
optfeature "Microsoft Excel file indexing" dev-libs/libxls
fi
ecm_pkg_postinst
}
|
GitWeb
