blob: 42773358881be72e340cb4d1b69e11c73a676cfc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="forceoptional"
ECM_TEST="optional"
KFMIN=5.70.0
QTMIN=5.14.2
VIRTUALX_REQUIRED="test"
inherit ecm kde.org optfeature
DESCRIPTION="File archiver by KDE"
HOMEPAGE="https://kde.org/applications/en/ark
https://utils.kde.org/projects/ark/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="amd64 arm64 ~ppc64 ~x86"
IUSE="zip"
BDEPEND="
sys-devel/gettext
"
RDEPEND="
app-arch/libarchive:=[bzip2,lzma,zlib]
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-frameworks/karchive-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemmodels-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/kpty-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
sys-libs/zlib
zip? ( >=dev-libs/libzip-1.2.0:= )
"
DEPEND="${RDEPEND}
>=dev-qt/qtconcurrent-${QTMIN}:5
"
PATCHES=(
"${FILESDIR}/${P}-CVE-2020-16116.patch"
"${FILESDIR}/${P}-CVE-2020-24654.patch"
)
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package zip LibZip)
)
ecm_src_configure
}
src_test() {
local myctestargs=(
-E "(plugins-clirartest)"
)
ecm_src_test
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "Optional dependencies:"
optfeature "rar archive creation/extraction" app-arch/rar
optfeature "rar archive extraction only" app-arch/unar app-arch/unrar
optfeature "7-Zip archive support" app-arch/p7zip
optfeature "lrz archive support" app-arch/lrzip
optfeature "markdown support in text previews" kde-misc/markdownpart:${SLOT} kde-misc/kmarkdownwebview:${SLOT}
fi
ecm_pkg_postinst
}
|
GitWeb