blob: 7d3ecfd59c3400d81412f4c50b308b66917cfcbe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit fcaps meson
MY_PV=$(ver_rs 3 -)
MY_PV="${MY_PV//_/-}"
DESCRIPTION="Efficient micro-compositor for running games"
HOMEPAGE="https://github.com/Plagman/gamescope"
SRC_URI="https://github.com/Plagman/${PN}/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64"
LICENSE="BSD-2"
SLOT="0"
IUSE="pipewire"
RDEPEND="
=dev-libs/libliftoff-0.3*
>=dev-libs/wayland-1.21
>=dev-libs/wayland-protocols-1.17
=gui-libs/wlroots-0.15*[X]
media-libs/libsdl2[video]
media-libs/vulkan-loader
sys-apps/hwdata
sys-libs/libcap
>=x11-libs/libdrm-2.4.109
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libxkbcommon
x11-libs/libXrender
x11-libs/libXres
x11-libs/libXtst
x11-libs/libXxf86vm
pipewire? ( >=media-video/pipewire-0.3:= )
"
DEPEND="
${RDEPEND}
dev-libs/stb
dev-util/vulkan-headers
"
BDEPEND="
dev-util/glslang
dev-util/wayland-scanner
"
S="${WORKDIR}/${PN}-${MY_PV}"
FILECAPS=(
cap_sys_nice usr/bin/${PN}
)
src_prepare() {
default
# Normally uses stb from a git submodule. Upstream does not ship a
# pkg-config file so we don't install one. Work around this using symlinks.
mkdir subprojects/stb || die
ln -snf "${ESYSROOT}"/usr/include/stb/* "${S}"/subprojects/packagefiles/stb/* subprojects/stb/ || die
}
src_configure() {
local emesonargs=(
--force-fallback-for=
$(meson_feature pipewire)
)
meson_src_configure
}
|
GitWeb
