blob: fb67180f23080b37cd8fdad8147f4e825d0b2d3c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
inherit flag-o-matic gnome.org meson python-any-r1
DESCRIPTION="Library providing a virtual terminal emulator widget"
HOMEPAGE="https://gitlab.gnome.org/GNOME/vte"
# Upstream is hostile and refuses to upload tarballs.
SRC_URI="https://gitlab.gnome.org/GNOME/vte/-/archive/${PV}/vte-${PV}.tar.bz2"
S="${WORKDIR}/vte-${PV}"
# Once SIXEL support ships (0.66 or later), might need xterm license (but code might be considered upgraded to LGPL-3+)
LICENSE="LGPL-3+ GPL-3+"
SLOT="2.91" # vte_api_version in meson.build
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="systemd"
DEPEND="
|| ( >=gui-libs/gtk-4.0.1:4 >=x11-libs/gtk+-3.24.22:3 )
>=x11-libs/cairo-1.0
>=dev-libs/fribidi-1.0.0
>=dev-libs/glib-2.60:2
>=x11-libs/pango-1.22.0
>=dev-libs/libpcre2-10.21
systemd? ( >=sys-apps/systemd-220:= )
>=app-arch/lz4-1.9
x11-libs/pango
"
RDEPEND="
!<x11-libs/vte-0.70.0:2.91
"
BDEPEND="
${PYTHON_DEPS}
dev-libs/libxml2:2
dev-util/glib-utils
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
src_prepare() {
default
use elibc_musl && eapply "${FILESDIR}"/${PN}-0.70.0-musl-W_EXITCODE.patch
}
src_configure() {
# Upstream don't support LTO & error out on it in meson.build (bug #926156)
filter-lto
local emesonargs=(
-Da11y=false
-Ddebug=false
-Ddocs=false
-Dgir=false
-Dfribidi=true # pulled in by pango anyhow
-Dglade=false
-Dgnutls=false
-Dgtk3=false
-Dgtk4=false
-Dicu=false
$(meson_use systemd _systemd)
-Dvapi=false
)
meson_src_configure
}
src_install() {
exeinto /usr/libexec/
doexe "${BUILD_DIR}"/src/vte-urlencode-cwd
insinto /etc/profile.d/
newins "${BUILD_DIR}"/src/vte.sh vte-${SLOT}.sh
newins "${BUILD_DIR}"/src/vte.csh vte-${SLOT}.csh
if use systemd; then
insinto /usr/lib/systemd/user/vte-spawn-.scode.d/
newins "${S}"/src/vte-spawn-.scope.conf defaults.conf
fi
einstalldocs
}
|
GitWeb