blob: 617af625e124893e71657e233166eefe9eb4a7ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
MY_P=${PN}-src-${PV}
DESCRIPTION="A fork of Mupen64 Nintendo 64 emulator, HLE RSP plugin"
HOMEPAGE="https://www.mupen64plus.org/"
SRC_URI="
https://github.com/mupen64plus/${PN}/releases/download/${PV}/${MY_P}.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
DEPEND="
>=games-emulation/mupen64plus-core-${PV}:0=
"
RDEPEND="
${DEPEND}
"
BDEPEND="
virtual/pkgconfig
"
src_prepare() {
default
# avoid implicitly appending CPU flags
sed -i -e 's:-mmmx::g' -e 's:-msse::g' projects/unix/Makefile || die
}
src_compile() {
MAKEARGS=(
# Note: please keep this in sync in all of mupen64plus-* packages
-C projects/unix
# this basically means: GNU userspace
UNAME=Linux
# verbose output
V=1
CROSS_COMPILE="${CHOST}-"
CC="$(tc-getCC)"
CXX="$(tc-getCXX)"
PKG_CONFIG="$(tc-getPKG_CONFIG)"
# usual CFLAGS, CXXFLAGS and LDFLAGS are respected
# so we can leave OPTFLAGS empty
OPTFLAGS=
# paths, some of them are used at compile time
PREFIX=/usr
LIBDIR=/usr/$(get_libdir)
# disable unwanted magic
LDCONFIG=:
INSTALL_STRIP_FLAG=
)
use amd64 && MAKEARGS+=( HOST_CPU=x86_64 )
use x86 && MAKEARGS+=( HOST_CPU=i386 )
emake "${MAKEARGS[@]}" all
}
src_install() {
emake "${MAKEARGS[@]}" DESTDIR="${D}" install
dodoc RELEASE
}
|