blob: 3eed5d63829a0f7209169b44169263411bb791b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils autotools toolchain-funcs
MY_P=kBuild-${PV/_/-}-src
DESCRIPTION="A makefile framework for writing simple makefiles for complex tasks"
HOMEPAGE="http://svn.netlabs.org/kbuild/wiki"
#SRC_URI="ftp://ftp.netlabs.org/pub/${PN}/${MY_P}.tar.gz"
SRC_URI="https://dev.gentoo.org/~polynomial-c/${MY_P}.tar.xz
https://dev.gentoo.org/~polynomial-c/${P}-tools_and_units_updates.patch.xz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE=""
DEPEND="sys-apps/texinfo
sys-devel/flex
sys-devel/gettext
virtual/yacc"
RDEPEND=""
S=${WORKDIR}/${MY_P/-src}
PATCHES=(
"${FILESDIR}/${PN}-unknown-configure-opt.patch"
"${FILESDIR}/${PN}-glibc-2.10.patch"
"${FILESDIR}/${PN}-0.1.5-gentoo-docdir.patch"
"${FILESDIR}/${PN}-0.1.9998_pre20120806-qa.patch"
"${FILESDIR}/${PN}-0.1.9998_pre20110817-kash-link-pthread.patch"
"${FILESDIR}/${PN}-0.1.9998_pre20110817-gold.patch"
"${FILESDIR}/${PN}-0.1.9998_pre20110817-gcc-4.7.patch"
"${WORKDIR}/${P}-tools_and_units_updates.patch"
)
src_prepare() {
rm -rf "${S}/kBuild/bin"
default
mv src/kmk/configure.{in,ac} || die
cd "${S}/src/kmk" || die
eautoreconf
cd "${S}/src/sed" || die
# AM_CONFIG_HEADER is obsolete since automake-1.13 (bug #467104)
sed 's@AM_CONFIG_HEADER@AC_CONFIG_HEADERS@' -i configure.ac || die
eautoreconf
sed -e "s@_LDFLAGS\.$(tc-arch)*.*=@& ${LDFLAGS}@g" \
-i "${S}"/Config.kmk || die #332225
tc-export CC RANLIB #AR does not work here
}
src_compile() {
kBuild/env.sh --full emake -f bootstrap.gmk AUTORECONF=true AR="$(tc-getAR)" \
|| die "bootstrap failed"
}
src_install() {
kBuild/env.sh kmk NIX_INSTALL_DIR=/usr PATH_INS="${D}" install \
|| die "install failed"
}
|
GitWeb
