dev-util/bless/bless-0.6.2-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit autotools gnome2 mono-env

DESCRIPTION="GTK# Hex Editor"
HOMEPAGE="https://github.com/afrantzis/Bless/"
SRC_URI="https://github.com/afrantzis/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
# EGIT_REPO_URI="https://github.com/afrantzis/bless/"
# EGIT_COMMIT="v${PV}"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="
	>=dev-lang/mono-1.1.14
	>=dev-dotnet/gtk-sharp-2.12.21:2
"
DEPEND="${RDEPEND}
	app-text/rarian
	>=sys-devel/gettext-0.15
	virtual/pkgconfig
"

# See bug 278162
# Waiting on nunit ebuild entering the tree
RESTRICT="test"
PATCHES=("${FILESDIR}/bless-0.6.2-range-disambiguation.patch")

pkg_setup() {
	mono-env_pkg_setup
}

src_prepare() {
	eautoreconf
	# The autoreconf expects INSTALL to have been copied over by autoconf
	touch "${S}/INSTALL"
	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		--enable-unix-specific \
		$(use_enable debug)
}

src_install() {
	default

	mv "${D}/usr/share/doc/${PN}" "${D}/usr/share/doc/${P}" || die "Unable to make documentation version-specific."
}