blob: 15ffd6bbac375d2e5bf0c3cb1952d1f869ce6028 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..13} pypy3 )
inherit distutils-r1 pypi
DESCRIPTION="Draws Python object reference graphs with graphviz"
HOMEPAGE="
https://github.com/mgedmin/objgraph/
https://pypi.org/project/objgraph/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
IUSE="doc"
RDEPEND="
media-gfx/graphviz
"
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# unhappy about pytest
tests.py::AtAddrsTest::test_at_addrs
)
case ${EPYTHON} in
pypy3)
EPYTEST_DESELECT+=(
# CPython GC
tests.py::ByTypeTest::test_new_garbage
# repr() mismatch
tests.py::StringRepresentationTest::test_short_repr_mocked_instance_method_bound
tests.py::StringRepresentationTest::test_short_repr_mocked_instance_method_bound_with_mocked_name
)
;;
python3.13)
EPYTEST_DESELECT+=(
# https://github.com/mgedmin/objgraph/issues/80
tests.py::StringRepresentationTest::test_edge_label_frame_locals
)
;;
esac
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
# TODO: figure out how to run doctests
epytest tests.py
}
python_install_all() {
use doc && local HTML_DOCS=( docs/* )
distutils-r1_python_install_all
}
|
GitWeb
