dev-libs/softhsm/softhsm-2.2.0-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit autotools eutils

DESCRIPTION="A software PKCS#11 implementation"
HOMEPAGE="http://www.opendnssec.org/"
SRC_URI="http://www.opendnssec.org/files/source/${P}.tar.gz"

KEYWORDS="~amd64 ~hppa ~x86"
IUSE="bindist libressl migration-tool test"
SLOT="2"
LICENSE="BSD"

RDEPEND="
	sys-devel/gcc:=[cxx]
	migration-tool? ( dev-db/sqlite:3 )
	!libressl? ( dev-libs/openssl:=[bindist=] )
	libressl? ( dev-libs/libressl )
	!=dev-libs/softhsm-2.0.0:0
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	test? ( dev-util/cppunit )
"

PATCHES=(
	"${FILESDIR}/${P}-build.patch"
	"${FILESDIR}/${P}-libressl.patch"
)
DOCS=( NEWS README.md )

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	econf \
		--disable-static \
		--localstatedir="${EROOT}var" \
		--with-crypto-backend=openssl \
		--disable-p11-kit \
		$(use_enable !bindist ecc) \
		$(use_enable !libressl gost) \
		$(use_with migration-tool migrate)
}

src_install() {
	default
	prune_libtool_files --modules
}