blob: 63f70913d55066c590bfdad01317b2d18ad9a083 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools toolchain-funcs
DESCRIPTION="A Debug Malloc Library"
HOMEPAGE="https://dmalloc.com"
SRC_URI="https://dmalloc.com/releases/${P}.tgz"
LICENSE="CC-BY-SA-3.0"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86"
IUSE="threads"
BDEPEND="sys-apps/texinfo"
DOCS=( NEWS README docs/NOTES docs/TODO )
PATCHES=(
# - Build objects twice, once -fPIC for shared.
# - Use DESTDIR.
# - Fix SONAME and NEEDED.
"${FILESDIR}"/${P}-Makefile.in.patch
# - Broken test, always returns false.
"${FILESDIR}"/${P}-cxx.patch
"${FILESDIR}"/${P}-ar.patch
# strdup() strndup() macros
"${FILESDIR}"/${P}-string-macros.patch
)
src_prepare() {
default
# - Add threads support.
use threads && eapply "${FILESDIR}"/${P}-threads.patch
# Respect CFLAGS/LDFLAGS. #337429
sed -i \
-e '/libdmalloc/ s:$(CC):& $(CFLAGS) $(LDFLAGS):g' \
-e 's|ar cr|$(AR) cr|g' \
Makefile.in || die
# Run autoconf for -cxx.patch.
eautoconf
}
src_configure() {
tc-export AR
econf \
--enable-cxx \
--enable-shlib \
$(use_enable threads)
}
src_compile() {
default
cd docs
makeinfo dmalloc.texi || die
}
src_test() {
emake heavy
}
src_install() {
default
newdoc ChangeLog.1 ChangeLog
dodoc docs/dmalloc.pdf
dodoc RELEASE.html docs/dmalloc.html
doinfo docs/dmalloc.info
# add missing symlinks, lazy
dosym lib${PN}.so.${PV} /usr/$(get_libdir)/lib${PN}.so
dosym lib${PN}.so.${PV} /usr/$(get_libdir)/lib${PN}.so.${PV%%.*}
for lib in cxx th thcxx; do
dosym lib${PN}${lib}.so.${PV} /usr/$(get_libdir)/lib${PN}${lib}.so
dosym lib${PN}${lib}.so.${PV} \
/usr/$(get_libdir)/lib${PN}${lib}.so.${PV%%.*}
done
rm "${ED}"/usr/$(get_libdir)/lib${PN}*.a || die
}
|
GitWeb