blob: 2dc0892a58efcd524ecbfd7abfdc210b39588dfc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
REAL_PN="Paper-Clip"
inherit gnome2-utils meson vala xdg
DESCRIPTION="Edit the title, author, keywords and more details of PDF documents"
HOMEPAGE="https://github.com/Diego-Ivan/Paper-Clip/"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/Diego-Ivan/${REAL_PN}.git"
else
SRC_URI="https://github.com/Diego-Ivan/${REAL_PN}/archive/v${PV}.tar.gz
-> ${P}.tar.gz"
S="${WORKDIR}/${REAL_PN}-${PV}"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-3+"
SLOT="0"
RESTRICT="test" # Only validations, appdata one fails.
RDEPEND="
app-text/poppler:=[cairo,introspection]
dev-libs/glib:2
dev-libs/gobject-introspection
dev-libs/libportal:=[gtk,introspection,vala]
gui-libs/gtk:4
gui-libs/libadwaita:1[introspection,vala]
"
DEPEND="
${RDEPEND}
"
BDEPEND="
$(vala_depend)
dev-libs/appstream-glib
dev-util/desktop-file-utils
"
DOCS=( README.md )
src_prepare() {
default
vala_setup
}
src_install() {
meson_src_install
einstalldocs
# Symlink "pdf-metadata-editor" (old name?) to "${PN}"
dosym -r /usr/bin/pdf-metadata-editor /usr/bin/${PN}
mv "${ED}"/usr/share/appdata "${ED}"/usr/share/metainfo || die
}
pkg_postinst() {
gnome2_schemas_update
xdg_pkg_postinst
}
pkg_postrm() {
gnome2_schemas_update
xdg_pkg_postrm
}
|
GitWeb
