blob: ae80765cc747b49819bd11bd1c9d6a0eef1226cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools vim-doc xdg
DESCRIPTION="Console file manager with vi(m)-like keybindings"
HOMEPAGE="https://vifm.info/"
if [[ ${PV} == 9999 ]] ; then
EGIT_REPO_URI="https://github.com/vifm/vifm"
inherit git-r3
else
SRC_URI="https://github.com/vifm/vifm/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="amd64 ~arm64 ppc x86"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="+extended-keys gtk +magic +vim +vim-syntax X"
DEPEND="
>=sys-libs/ncurses-5.9-r3:=
magic? ( sys-apps/file )
gtk? ( x11-libs/gtk+:2 )
X? ( x11-libs/libX11 )
"
RDEPEND="
${DEPEND}
vim? ( || ( app-editors/vim app-editors/gvim ) )
vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
"
# "Either perl or Vim is necessary to generate tags for documentation in Vim's format." from configure
BDEPEND="|| ( dev-lang/perl app-editors/vim )"
src_prepare() {
default
eautoreconf
}
src_configure() {
# developer just turns off optimisations and adds -Werror again
# bug #855386
econf \
--disable-developer \
--disable-werror \
$(use_enable extended-keys) \
$(use_with magic libmagic) \
$(use_with gtk) \
$(use_with X X11)
}
src_install() {
default
if use vim; then
local t
for t in app plugin; do
insinto /usr/share/vim/vimfiles/"${t}"
doins -r data/vim/doc/${t}/${PN}*
done
fi
if use vim-syntax; then
local t
for t in ftdetect ftplugin syntax; do
insinto /usr/share/vim/vimfiles/"${t}"
doins -r data/vim/${t}/${PN}*
done
fi
}
pkg_postinst() {
xdg_pkg_postinst
if use vim; then
update_vim_helptags
if [[ -n ${REPLACING_VERSIONS} ]]; then
elog
elog "You don't need to copy or link any files for"
elog " the vim plugin and documentation to work anymore."
elog "If you copied any vifm files to ~/.vim/ manually"
elog " in earlier vifm versions, please delete them."
fi
elog
elog "To use vim in vifm to view the documentation"
elog " edit ~/.vifm/vifmrc and set vimhelp instead of novimhelp"
elog
fi
}
pkg_postrm() {
xdg_pkg_postrm
use vim && update_vim_helptags
}
|
GitWeb