blob: 718e4cae3c65d46e57a9d3382a3c8e37202beeaf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
DESCRIPTION="getopt(1) replacement supporting GNU-style long options"
HOMEPAGE="http://frodo.looijaard.name/project/getopt/"
SRC_URI="http://frodo.looijaard.name/system/files/software/getopt/${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~x64-cygwin ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="nls"
RDEPEND="nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
nls? ( sys-devel/gettext )"
PATCHES=(
"${FILESDIR}"/${PN}-1.1.5-libintl.patch
"${FILESDIR}"/${PN}-1.1.5-setlocale.patch
"${FILESDIR}"/${PN}-1.1.6-longrename.patch
"${FILESDIR}"/${PN}-1.1.4-irix.patch
)
src_compile() {
local nogettext="1"
local libintl=""
local libcgetopt=1
if use nls; then
nogettext=0
has_version sys-libs/glibc || libintl="-lintl"
fi
[[ ${CHOST} == *-aix* ]] && libcgetopt=0
[[ ${CHOST} == *-irix* ]] && libcgetopt=0
[[ ${CHOST} == *-interix* ]] && libcgetopt=0
emake CC="$(tc-getCC)" prefix="${EPREFIX}/usr" \
LIBCGETOPT=${libcgetopt} \
WITHOUT_GETTEXT=${nogettext} LIBINTL=${libintl} \
CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
}
src_install() {
use nls && emake prefix="${EPREFIX}/usr" DESTDIR="${D}" install_po
newbin getopt getopt-long
# at least on interix, the system getopt is ... broken...
# util-linux, which would provide the getopt binary, does not build &
# install on interix/prefix, so, this has to provide it.
[[ ${CHOST} == *-interix* || ${CHOST} == *-mint* ]] && \
dosym getopt-long /usr/bin/getopt
newman getopt.1 getopt-long.1
dodoc getopt-*sh
}
|
GitWeb
