blob: 02222dc3ac5c34223d0697ff40bd347d73a82fa5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="false"
KDE_ORG_CATEGORY="sdk"
KDE_ORG_NAME="dolphin-plugins"
MY_PLUGIN_NAME="mountiso"
KFMIN=5.106.0
PVCUT=$(ver_cut 1-3)
QTMIN=5.15.9
inherit ecm gear.kde.org
DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
LICENSE="GPL-2+"
SLOT="5"
KEYWORDS="amd64 ~arm64 ~loong ~ppc64 x86"
IUSE=""
DEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-apps/dolphin-${PVCUT}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
"
RDEPEND="${DEPEND}"
src_prepare() {
ecm_src_prepare
# kxmlgui, qtnetwork only required by dropbox
ecm_punt_qt_module Network
ecm_punt_kf_module XmlGui
# delete non-${PN} translations
find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
}
src_configure() {
local mycmakeargs=(
-DBUILD_${MY_PLUGIN_NAME}=ON
-DBUILD_bazaar=OFF
-DBUILD_dropbox=OFF
-DBUILD_git=OFF
-DBUILD_hg=OFF
-DBUILD_svn=OFF
)
ecm_src_configure
}
src_install() {
ecm_src_install
rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
}
|
GitWeb
