blob: f903010ac4a5159f7a0e58d384d3024cd843b519 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools toolchain-funcs
DESCRIPTION="Package maintenance system for Debian"
HOMEPAGE="https://packages.qa.debian.org/dpkg"
SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.xz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+bzip2 libmd +lzma nls selinux static-libs test +update-alternatives +zlib"
RESTRICT="!test? ( test )"
RDEPEND="
>=app-arch/tar-1.34-r1
>=dev-lang/perl-5.14.2:=
sys-libs/ncurses:=[unicode(+)]
bzip2? ( app-arch/bzip2 )
libmd? ( app-crypt/libmd )
lzma? ( app-arch/xz-utils )
nls? ( virtual/libintl )
selinux? ( sys-libs/libselinux )
zlib? ( >=sys-libs/zlib-1.1.4 )
"
DEPEND="
${RDEPEND}
app-arch/xz-utils
virtual/pkgconfig
test? (
dev-perl/IO-String
dev-perl/Test-Pod
virtual/perl-Test-Harness
)
"
BDEPEND="
app-alternatives/lex
nls? (
app-text/po4a
>=sys-devel/gettext-0.18.2
)
"
RDEPEND+=" selinux? ( sec-policy/selinux-dpkg )"
DOCS=(
ChangeLog
THANKS
TODO
)
PATCHES=(
"${FILESDIR}"/${PN}-1.18.12-flags.patch
"${FILESDIR}"/${PN}-1.18.12-rsyncable.patch
"${FILESDIR}"/${PN}-1.20.5-dpkg_buildpackage-test.patch
"${FILESDIR}"/${PN}-1.20.12-m4-stdio.patch
)
src_prepare() {
default
sed -i -e 's|\<ar\>|${AR}|g' t-func/deb-format.at t-func/testsuite || die
eautoreconf
}
src_configure() {
tc-export AR CC
econf \
$(use_enable nls) \
$(use_enable update-alternatives) \
$(use_with bzip2 libbz2) \
$(use_with libmd) \
$(use_with lzma liblzma) \
$(use_with selinux libselinux) \
$(use_with zlib libz) \
--enable-unicode \
--disable-compiler-warnings \
--disable-dselect \
--disable-start-stop-daemon \
--localstatedir="${EPREFIX}"/var
}
src_compile() {
emake AR="$(tc-getAR)"
}
src_install() {
default
keepdir \
/usr/$(get_libdir)/db/methods/{mnt,floppy,disk} \
/var/lib/dpkg/{alternatives,info,parts,updates}
find "${ED}" -name '*.la' -delete || die
if ! use static-libs; then
find "${ED}" -name '*.a' -delete || die
fi
}
|
GitWeb