1 files changed, 56 insertions, 0 deletions
diff --git a/sys-cluster/ucx/ucx-1.13.0.ebuild b/sys-cluster/ucx/ucx-1.13.0.ebuild
new file mode 100644
index 000000000000..983466a7cf98
--- /dev/null
+++ b/sys-cluster/ucx/ucx-1.13.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_PV=${PV/_/-}
+DESCRIPTION="Unified Communication X"
+HOMEPAGE="https://www.openucx.org"
+SRC_URI="https://github.com/openucx/ucx/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 -riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="+numa +openmp"
+
+RDEPEND="
+	sys-libs/binutils-libs:=
+	numa? ( sys-process/numactl )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.13.0-drop-werror.patch
+	"${FILESDIR}"/${PN}-1.13.0-fix-bashisms.patch
+	"${FILESDIR}"/${PN}-1.13.0-fix-fcntl-include-musl.patch
+	"${FILESDIR}"/${P}-binutils-2.39-ptr-typedef.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	BASE_CFLAGS="" econf \
+		--disable-compiler-opt \
+		--without-fuse3 \
+		--without-go \
+		$(use_enable numa) \
+		$(use_enable openmp)
+}
+
+src_compile() {
+	BASE_CFLAGS="" emake
+}