1 files changed, 0 insertions, 102 deletions
diff --git a/net-p2p/bitcoin-cli/bitcoin-cli-0.21.1.ebuild b/net-p2p/bitcoin-cli/bitcoin-cli-0.21.1.ebuild
deleted file mode 100644
index 3c3bac923348..000000000000
--- a/net-p2p/bitcoin-cli/bitcoin-cli-0.21.1.ebuild
+++ /dev/null
@@ -1,102 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools bash-completion-r1
-
-BITCOINCORE_COMMITHASH="194b9b8792d9b0798fdb570b79fa51f1d1f5ebaf"
-KNOTS_PV="${PV}.knots20210629"
-KNOTS_P="bitcoin-${KNOTS_PV}"
-
-DESCRIPTION="Command-line JSON-RPC client specifically for interfacing with bitcoind"
-HOMEPAGE="https://bitcoincore.org/ https://bitcoinknots.org/"
-SRC_URI="
-	https://github.com/bitcoin/bitcoin/archive/${BITCOINCORE_COMMITHASH}.tar.gz -> bitcoin-v${PV}.tar.gz
-	https://bitcoinknots.org/files/0.21.x/${KNOTS_PV}/${KNOTS_P}.patches.txz -> ${KNOTS_P}.patches.tar.xz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="knots"
-
-DEPEND="
-	>=dev-libs/boost-1.58.0:=[threads(+)]
-	dev-libs/libevent:=
-	>=dev-libs/univalue-1.0.4:=
-"
-RDEPEND="${DEPEND}"
-BDEPEND="
-	>=sys-devel/autoconf-2.69
-	>=sys-devel/automake-1.13
-"
-
-DOCS=(
-	doc/release-notes.md
-)
-
-S="${WORKDIR}/bitcoin-${BITCOINCORE_COMMITHASH}"
-
-pkg_pretend() {
-	if use knots; then
-		elog "You are building ${PN} from Bitcoin Knots."
-		elog "For more information, see:"
-		elog "https://bitcoinknots.org/files/0.21.x/${KNOTS_PV}/${KNOTS_P}.desc.html"
-	else
-		elog "You are building ${PN} from Bitcoin Core."
-		elog "For more information, see:"
-		elog "https://bitcoincore.org/en/2021/05/01/release-${PV}/"
-	fi
-}
-
-src_prepare() {
-	local knots_patchdir="${WORKDIR}/${KNOTS_P}.patches/"
-
-	eapply "${knots_patchdir}/${KNOTS_P}.syslibs.patch"
-
-	if use knots; then
-		eapply "${knots_patchdir}/${KNOTS_P}.f.patch"
-		eapply "${knots_patchdir}/${KNOTS_P}.branding.patch"
-		eapply "${knots_patchdir}/${KNOTS_P}.ts.patch"
-	fi
-
-	eapply_user
-
-	echo '#!/bin/true' >share/genbuild.sh || die
-	mkdir -p src/obj || die
-	echo "#define BUILD_SUFFIX gentoo${PVR#${PV}}" >src/obj/build.h || die
-
-	eautoreconf
-	rm -r src/leveldb src/secp256k1 || die
-}
-
-src_configure() {
-	local my_econf=(
-		--disable-asm
-		--without-qtdbus
-		--without-qrencode
-		--without-miniupnpc
-		--disable-tests
-		--disable-wallet
-		--disable-zmq
-		--enable-util-cli
-		--disable-util-tx
-		--disable-util-wallet
-		--disable-bench
-		--without-libs
-		--without-daemon
-		--without-gui
-		--disable-fuzz
-		--disable-ccache
-		--disable-static
-		--with-system-univalue
-	)
-	econf "${my_econf[@]}"
-}
-
-src_install() {
-	default
-
-	newbashcomp contrib/bitcoin-cli.bash-completion ${PN}
-}