1 files changed, 68 insertions, 0 deletions
diff --git a/net-analyzer/vnstat/vnstat-2.0.ebuild b/net-analyzer/vnstat/vnstat-2.0.ebuild
new file mode 100644
index 000000000000..8838083fcd65
--- /dev/null
+++ b/net-analyzer/vnstat/vnstat-2.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit systemd user
+
+DESCRIPTION="Console-based network traffic monitor that keeps statistics of network usage"
+HOMEPAGE="https://humdi.net/vnstat/"
+SRC_URI="https://humdi.net/vnstat/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gd selinux test"
+
+COMMON_DEPEND="
+	dev-db/sqlite
+	gd? ( media-libs/gd[png] )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	test? ( dev-libs/check )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	selinux? ( sec-policy/selinux-vnstatd )
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.17-conf.patch
+	"${FILESDIR}"/${PN}-1.17-drop-root.patch
+	"${FILESDIR}"/${PN}-1.17-run.patch
+)
+
+pkg_setup() {
+	enewgroup vnstat
+	enewuser vnstat -1 -1 /var/lib/vnstat vnstat
+}
+
+src_compile() {
+	emake ${PN} ${PN}d $(usex gd ${PN}i '')
+}
+
+src_install() {
+	use gd && dobin vnstati
+	dobin vnstat vnstatd
+
+	exeinto /usr/share/${PN}
+	newexe "${FILESDIR}"/vnstat.cron-r1 vnstat.cron
+
+	insinto /etc
+	doins cfg/vnstat.conf
+	fowners root:vnstat /etc/vnstat.conf
+
+	keepdir /var/lib/vnstat
+	fowners vnstat:vnstat /var/lib/vnstat
+
+	newconfd "${FILESDIR}"/vnstatd.confd-r1 vnstatd
+	newinitd "${FILESDIR}"/vnstatd.initd-r2 vnstatd
+
+	systemd_newunit "${FILESDIR}"/vnstatd.systemd vnstatd.service
+	systemd_newtmpfilesd "${FILESDIR}"/vnstatd.tmpfile vnstatd.conf
+
+	use gd && doman man/vnstati.1
+	doman man/vnstat.1 man/vnstatd.1
+
+	newdoc INSTALL README.setup
+	dodoc CHANGES README UPGRADE FAQ examples/vnstat.cgi
+}