1 files changed, 60 insertions, 0 deletions
diff --git a/kde-apps/kmix/kmix-20.04.2.ebuild b/kde-apps/kmix/kmix-20.04.2.ebuild
new file mode 100644
index 000000000000..650b2919511b
--- /dev/null
+++ b/kde-apps/kmix/kmix-20.04.2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="false"
+KFMIN=5.70.0
+PLASMA_MINIMAL=5.16.5
+QTMIN=5.14.1
+inherit ecm kde.org
+
+DESCRIPTION="Volume control gui based on KDE Frameworks"
+HOMEPAGE="https://kde.org/applications/multimedia/org.kde.kmix"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="alsa plasma pulseaudio"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	alsa? ( >=media-libs/alsa-lib-1.0.14a )
+	plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
+	pulseaudio? (
+		dev-libs/glib:2
+		media-libs/libcanberra
+		>=media-sound/pulseaudio-0.9.12
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PLASMA_MINIMAL}:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-19.12.3-no-more-kcm_phonon.patch" ) # bug 716092
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package alsa ALSA)
+		$(cmake_use_find_package plasma KF5Plasma)
+		$(cmake_use_find_package pulseaudio Canberra)
+		$(cmake_use_find_package pulseaudio PulseAudio)
+	)
+
+	ecm_src_configure
+}