1 files changed, 49 insertions, 0 deletions
diff --git a/dev-ruby/ruby-clutter/ruby-clutter-2.2.5.ebuild b/dev-ruby/ruby-clutter/ruby-clutter-2.2.5.ebuild
new file mode 100644
index 000000000000..995319ccfeb3
--- /dev/null
+++ b/dev-ruby/ruby-clutter/ruby-clutter-2.2.5.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+USE_RUBY="ruby19 ruby20 ruby21 ruby22"
+
+inherit virtualx ruby-ng-gnome2
+
+DESCRIPTION="Ruby Clutter bindings"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RUBY_S=ruby-gnome2-all-${PV}/clutter
+
+DEPEND+=" media-libs/clutter"
+RDEPEND+=" media-libs/clutter"
+
+ruby_add_bdepend ">=dev-ruby/ruby-glib2-${PV}"
+ruby_add_rdepend ">=dev-ruby/ruby-cairo-gobject-${PV}
+	>=dev-ruby/ruby-gobject-introspection-${PV}"
+
+all_ruby_prepare() {
+	# Avoid unneeded dependency on test-unit-notify.
+	sed -i -e '/notify/ s:^:#:' \
+		../gobject-introspection/test/gobject-introspection-test-utils.rb \
+		../cairo-gobject/test/cairo-gobject-test-utils.rb \
+		test/clutter-test-utils.rb || die
+
+	# Avoid compilation of dependencies during test.
+	sed -i -e '/system/,/^  end/ s:^:#:' test/run-test.rb || die
+}
+
+each_ruby_configure() {
+	:
+}
+
+each_ruby_compile() {
+	:
+}
+
+each_ruby_test() {
+	VIRTUALX_COMMAND="${RUBY} test/run-test.rb"
+	virtualmake || die
+}
+
+each_ruby_install() {
+	each_fakegem_install
+}