xfce-base/xfce4-session: Bump to 4.14.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/xfce-base/xfce4-session/Manifest b/xfce-base/xfce4-session/Manifest
index 9bf66c45abcd..f748152b7e8e 100644
--- a/xfce-base/xfce4-session/Manifest
+++ b/xfce-base/xfce4-session/Manifest
@@ -1 +1,2 @@
 DIST xfce4-session-4.14.1.tar.bz2 836607 BLAKE2B 916589884e47ce3224c4a6d5537dc7b03d18ec56009ae3e2b4db01d9614a18d1db0f14d3a732b0ed72b924a56831c37111f08068b39b43dab85a39d82ea38cac SHA512 af797e33145311015ca6444b929d82c4e321f76defe773aba723d0a373f894399216e043b45e0669dd1c9aa1ad3cd2dcfd422352fd2381b7425bb310be66c92b
+DIST xfce4-session-4.14.2.tar.bz2 841878 BLAKE2B e59be7bf622c40df60051643e52e703896d994f3729167e532a8594d19e139050b3dd995a153b0397c5aee2cbce9880abf8fdd011115db999508eede8de0034e SHA512 ab67cb576ac4880f41cf8eec05539a733da066c50913c9c2c9116ed3129b342aa3ca005ea5b46a733780cd062a4454d530240d89660b6c48a2045c821f7c490f
diff --git a/xfce-base/xfce4-session/xfce4-session-4.14.2.ebuild b/xfce-base/xfce4-session/xfce4-session-4.14.2.ebuild
new file mode 100644
index 000000000000..251ab43f61cc
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.14.2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="https://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="elogind nls policykit systemd +xscreensaver"
+
+COMMON_DEPEND="x11-apps/iceauth
+	>=dev-libs/glib-2.42
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libSM
+	x11-libs/libwnck:3
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.12:=
+	>=xfce-base/libxfce4ui-4.12.1:=[gtk3(+)]
+	>=xfce-base/xfconf-4.12:=
+	policykit? ( >=sys-auth/polkit-0.102 )"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	nls? ( x11-misc/xdg-user-dirs )
+	xscreensaver? ( || (
+		xfce-extra/xfce4-screensaver
+		>=x11-misc/xscreensaver-5.26
+		>=x11-misc/xlockmore-5.43
+		x11-misc/slock
+		x11-misc/alock[pam]
+	) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+REQUIRED_USE="elogind? ( policykit )
+	systemd? ( policykit )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.10.1-alock_support_to_xflock4.patch
+# TODO: this patch needs updating for the new version, and finding
+# upstream bug.
+#	"${FILESDIR}"/${PN}-4.12.1-light-locker_support_to_xflock4.patch
+)
+
+src_configure() {
+	local myconf=(
+		$(use_enable policykit polkit)
+		--with-xsession-prefix="${EPREFIX}"/usr
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4 || die
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}