www-client/opera: bump to 77.0.4054.146

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 133 insertions, 0 deletions

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index dd3e0d53ff7b..5264a6b6866e 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1,2 +1,3 @@
 DIST opera-ffmpeg-codecs-91.0.4472.19.tar.xz 1383552 BLAKE2B f278bcef8ec013e24bb5293f50cb82be8b9381d181d6e837e8ed0f5b5f7fbdbde4d6e16e30787def46c333f2d6fb7573c7fbdf09697400d9429b3bc154a8da92 SHA512 58c419e469f257e5d3a7ec2fb18885a61aa8f4d6a56f8f6922fb4d4cecbfd9267d7cd72a451d1b23ee88bad0bebd83affa0850a1bbf7b2b26dac398752c7e905
+DIST opera-stable_77.0.4054.146_amd64.deb 82485584 BLAKE2B cbc8240af50559b8ef0a8adab0750c6a0a787b3fc71c3759e9d100fd3cdf3af3a3469bd5eff03680f3d0ecd3566d41006750bd45c5ca45279b6593d270c9544b SHA512 7190f3e5425955b152e55e71c4feaa3e83dd5984680a55df3b05e9e80d283a33b27b0dbd63a04e12c4bc03f5e5530e69651631e151f458b4a24b9572e80f7365
 DIST opera-stable_77.0.4054.90_amd64.deb 74362012 BLAKE2B 27ccbbebdc16fea2cd8fff3af1b0df891815264bdbc0ff08bb3bd057356573ed130f4a745debac6ccea0e68f7e7898483c074ae1238a7f7cbbfd3b6bfcd574c9 SHA512 175a7a532ad41b9da5384831453738f242f3f7e340e001b834e132fe1a77329df6cc0c4c1ee210409bc71887c27c9c10a6df549aa3ed617938a083a1342e389e
diff --git a/www-client/opera/opera-77.0.4054.146.ebuild b/www-client/opera/opera-77.0.4054.146.ebuild
new file mode 100644
index 000000000000..ac62c3431ac4
--- /dev/null
+++ b/www-client/opera/opera-77.0.4054.146.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib pax-utils unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="91.0.4472.19"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
+	proprietary-codecs? (
+		https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	rm -r "usr/share/lintian" || die
+
+	# fix docs
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}