www-client/opera-developer: Version bump.

Package-Manager: Portage-2.3.8, Repoman-2.3.3

2 files changed, 90 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index 6ade14af1afe..69adac2d7476 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1 +1,2 @@
 DIST opera-developer_49.0.2695.0_amd64.deb 50335766 SHA256 1afa7ef055a384100a8de902d8f1467011f6a1465fd62ed568c1e4842ab00d43 SHA512 38b409693ad09b0383643b6d6656e577809a503e0a18ef12521736c287cb487f49c5780118a8dc2fbefc7a2d032dafed3cc605faf5df30694bc18694fb328eed WHIRLPOOL 6290b09129267894d48f83f6026de53de2bd9a25febf632c8257750fb144ee0d52a7a2a3dc70ae08a1da87ff3605bd7c9f98f5e14b964407ad26929d79df3f9c
+DIST opera-developer_49.0.2705.0_amd64.deb 50262370 SHA256 bc8d323cdb02f48265741a02961e9fafc6eb3e0bc86ec42f9075be71a2730192 SHA512 3ce5ecf5fe038b7fbeb3fc37f170cb4c6bd54c41a6e49fd92a582c569958dc5262062edeb2e43d6f295e5eb00991ae82794a908ade0933a72b5d52764075b82a WHIRLPOOL f64026a277a75ec14b05a0007e646dbab15be25dff45a4456b50ce142f9043dffde5a7733928a6a7622d62c24ac0d6596258cd1e9e21cb693924534f10a98674
diff --git a/www-client/opera-developer/opera-developer-49.0.2705.0.ebuild b/www-client/opera-developer/opera-developer-49.0.2705.0.ebuild
new file mode 100644
index 000000000000..8954f5fdccb1
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-49.0.2705.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="http://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="http://get.geo.opera.com/pub/"
+SRC_URI="
+	amd64?	( "${SRC_URI_BASE}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb" )
+"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}/copyright || die
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}