www-client/qutebrowser: upgrade to 2.2.0

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Stefan Strogin <steils@gentoo.org>

3 files changed, 97 insertions, 1 deletions

diff --git a/www-client/qutebrowser/Manifest b/www-client/qutebrowser/Manifest
index d703d5dba821..c4d3eae6bff7 100644
--- a/www-client/qutebrowser/Manifest
+++ b/www-client/qutebrowser/Manifest
@@ -1 +1,2 @@
 DIST qutebrowser-2.1.1.tar.gz 6249239 BLAKE2B 941742728f305539b07f2c97198cb3154a2c9d60da3a25175c34875d647fae8f802deaf906ce688a3f81327560f8d9a740314cfdd8dc3aac767bd3aaec30f14d SHA512 85c81454406e25a347866984059923500a23dfe9d2427324d6998a9738962155442b69e3b6318c2683fb7790ba908e8486ea0d42073c38d7a5a1f249577c2b5d
+DIST qutebrowser-2.2.0.tar.gz 6297885 BLAKE2B c43d5fdefe4fdabf479b7575ffc1582340aa6ca3add7f717a4d46ebe24fd086c26e57bee0932262e997abf5a2ce9c636732c83d8659617b16f9a040c196fad68 SHA512 79cc35d47a48d4eef8abb95082aa047a63356f53ac94027b48fbd679621f172e5fa4863af21e2398c6ec37b554871ca96e7338381aee2e0b01f6e1d661823fbc
diff --git a/www-client/qutebrowser/qutebrowser-2.2.0.ebuild b/www-client/qutebrowser/qutebrowser-2.2.0.ebuild
new file mode 100644
index 000000000000..7d86502435d3
--- /dev/null
+++ b/www-client/qutebrowser/qutebrowser-2.2.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit desktop distutils-r1 optfeature xdg-utils
+
+DESCRIPTION="A keyboard-driven, vim-like browser based on PyQt5 and QtWebEngine"
+HOMEPAGE="https://www.qutebrowser.org/ https://github.com/qutebrowser/qutebrowser"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="scripts test"
+
+BDEPEND="
+	app-text/asciidoc"
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/importlib_resources[${PYTHON_USEDEP}]' python3_{7,8})
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/markupsafe[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt5[${PYTHON_USEDEP},declarative,multimedia,gui,network,opengl,printsupport,sql,widgets]
+	dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.4.1[${PYTHON_USEDEP},libyaml]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests setup.py
+
+# Tests restricted as the deplist (misc/requirements/requirements-tests.txt)
+# isn't complete and X11 is required in order to start up qutebrowser.
+RESTRICT="test"
+
+python_compile_all() {
+	a2x -f manpage doc/${PN}.1.asciidoc || die "Failed generating man page"
+}
+
+python_install_all() {
+	doman doc/${PN}.1
+	domenu misc/org.${PN}.${PN}.desktop
+	doicon -s scalable icons/${PN}.svg
+
+	if use scripts; then
+		insinto /usr/share/qutebrowser/userscripts/
+		doins misc/userscripts/README.md
+		exeinto /usr/share/qutebrowser/userscripts/
+		doexe misc/userscripts/add-nextcloud-bookmarks \
+		      misc/userscripts/add-nextcloud-cookbook \
+		      misc/userscripts/cast \
+		      misc/userscripts/dmenu_qutebrowser \
+		      misc/userscripts/format_json \
+		      misc/userscripts/getbib \
+		      misc/userscripts/kodi \
+		      misc/userscripts/open_download \
+		      misc/userscripts/openfeeds \
+		      misc/userscripts/password_fill \
+		      misc/userscripts/qr \
+		      misc/userscripts/qute-bitwarden \
+		      misc/userscripts/qutedmenu \
+		      misc/userscripts/qute-keepass \
+		      misc/userscripts/qute-keepassxc \
+		      misc/userscripts/qute-lastpass \
+		      misc/userscripts/qute-pass \
+		      misc/userscripts/readability \
+		      misc/userscripts/readability-js \
+		      misc/userscripts/ripbang \
+		      misc/userscripts/rss \
+		      misc/userscripts/taskadd \
+		      misc/userscripts/tor_identity \
+		      misc/userscripts/view_in_mpv
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "PDF display support" www-plugins/pdfjs
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
diff --git a/www-client/qutebrowser/qutebrowser-9999.ebuild b/www-client/qutebrowser/qutebrowser-9999.ebuild
index a46589e92234..603c6acf96cc 100644
--- a/www-client/qutebrowser/qutebrowser-9999.ebuild
+++ b/www-client/qutebrowser/qutebrowser-9999.ebuild
@@ -29,7 +29,9 @@ RDEPEND="
 	dev-python/pypeg2[${PYTHON_USEDEP}]
 	dev-python/PyQt5[${PYTHON_USEDEP},declarative,multimedia,gui,network,opengl,printsupport,sql,widgets]
 	dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
-	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP},libyaml]
+	>=dev-python/pyyaml-5.4.1[${PYTHON_USEDEP},libyaml]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
 "
 
 distutils_enable_tests setup.py