sys-libs/llvm-libunwind: Bump to 6.0.0rc2

2 files changed, 94 insertions, 0 deletions

diff --git a/sys-libs/llvm-libunwind/Manifest b/sys-libs/llvm-libunwind/Manifest
index d4b6ec238b5a..93ca54facf22 100644
--- a/sys-libs/llvm-libunwind/Manifest
+++ b/sys-libs/llvm-libunwind/Manifest
@@ -1,5 +1,7 @@
+DIST libcxx-6.0.0rc2.src.tar.xz 1554124 BLAKE2B c1d270c4c102c7622138e00628bf863f4047018ecf859386358449da2b7afdf2fe7a9cf969fa96f678960fd4cc343c26e89d6e95e594eeacef3d0d18157f9cff SHA512 3f0a032c4670076ead80bb03b3b7a565dfaf6526c9309f4453a455463038d3e7960bf93f2393f6dd2bd8b7f1ea145555b9599edae54dba7ede97cf0d8240cc4f
 DIST libunwind-3.8.1.src.tar.xz 60596 BLAKE2B e200beab1388dc73a4ed6b1be0c4931124e48e21a3d5cc0bf01ac2ce57bbc2295bd0f72acb8fc08556aed963f0cb220bd3e47c3c953f570cf2860ae822a270c7 SHA512 2a60d7c4b0aee6c58f50089ac9fa2b756ab1d74faaee32f7436ddace4510589c7ffdd20478919966ed2fa8a23ee1b5d1b26115dbd8ee2834b00b5bcd61d00b14
 DIST libunwind-3.9.0.src.tar.xz 61764 BLAKE2B 215aa7cabf9e5d8d3e3dfc3bad50f0aad1b4d2d6bef96ac4c14d987b6aa4afd0a1c0f186d63d84edcc822fd8495a000b2a24899e61176831e0ddfabea1d5c3c2 SHA512 dce384bea99ed61b363b847e20946fc9d70377389a227cc7054fbaa916e7cb5ba0b9d89f0df6ed33409dbf38beefd3654c18c1abcf0e50b5d0315ce0135a1d25
 DIST libunwind-3.9.1.src.tar.xz 61788 BLAKE2B bab410d714e2dc012273997bb3fb3c366f64608b712eae15f8c08a2b049b6bdba0660a1f4942906e2e9cd7b11563c8a5b3007b92b1485c32036ac84f55fe7053 SHA512 a80f5d0660e209f5bf709316b5df2ca63b9f0db49f5f74dfe9c9e580c654f61a15acc071a739fdb84baf5ffa9420b92498f8560331173642d80f6b74e1e2afb7
 DIST libunwind-4.0.1.src.tar.xz 63388 BLAKE2B f49772beabaa8519a5f8dbbaef9c2d6554468a66b89a5f012946d59f772fe864809a5c95b726bcb4c059ca551a4eb023a88f4fa618756b34fef2058e272467e6 SHA512 8a0552a8ab830010d81420f4b778a3b831bff85b19bcce972958fc30e1ba5a2fa26a3deba499985a43dd7a103690775f6a20e7b3edda55f4eaff3541002d6b59
 DIST libunwind-5.0.1.src.tar.xz 72180 BLAKE2B da1fbb92e9953d018a3c30290ceda9a2a18c21b5c908d9ff65979158bd06b8866eb74f078d12832e2aed7d0332c996262e3b2a1341844eb933ba3de5fb41ff98 SHA512 6c0f7a286c1ffa46769685ee36604cd90ed40470e1c3d3ef03c46bcc9e5f9e36e68a0a1f67b9b300823170b48c9b8d2db4625afd885f1d024905db1dffd9fc49
+DIST libunwind-6.0.0rc2.src.tar.xz 76612 BLAKE2B 60420b8d913edb78f6f639e37e453810f538e2acb8b5772081f09d3d1ee9fd3787f842e94ccb0bb51b5410bacb7a2092a9d381d9687b79ff813de6ce837e195d SHA512 bfb04cea41c741351bada27e1c7510d00fa39332c781a6833979d64ddf754b1b2f63f4c2aa75111cb287d7eb6d0fd4bc2bc7407343038e86644743651da112a6
diff --git a/sys-libs/llvm-libunwind/llvm-libunwind-6.0.0_rc2.ebuild b/sys-libs/llvm-libunwind/llvm-libunwind-6.0.0_rc2.ebuild
new file mode 100644
index 000000000000..0305ac6b38cb
--- /dev/null
+++ b/sys-libs/llvm-libunwind/llvm-libunwind-6.0.0_rc2.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+# (needed due to CMAKE_BUILD_TYPE != Gentoo)
+CMAKE_MIN_VERSION=3.7.0-r1
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+inherit cmake-multilib llvm python-any-r1
+
+MY_P=libunwind-${PV/_/}.src
+LIBCXX_P=libcxx-${PV/_/}.src
+
+DESCRIPTION="C++ runtime stack unwinder from LLVM"
+HOMEPAGE="https://github.com/llvm-mirror/libunwind"
+SRC_URI="http://prereleases.llvm.org/${PV/_//}/${MY_P}.tar.xz
+	test? ( http://prereleases.llvm.org/${PV/_//}/${LIBCXX_P}.tar.xz )"
+
+LICENSE="|| ( UoI-NCSA MIT )"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug +static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="!sys-libs/libunwind"
+# llvm-6 for new lit options
+DEPEND="
+	>=sys-devel/llvm-6
+	test? (
+		sys-libs/libcxx[${MULTILIB_USEDEP}]
+		$(python_gen_any_dep 'dev-python/lit[${PYTHON_USEDEP}]') )"
+
+S=${WORKDIR}/${MY_P}
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+python_check_deps() {
+	has_version "dev-python/lit[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	einfo "Unpacking ${MY_P}.tar.xz ..."
+	tar -xf "${DISTDIR}/${MY_P}.tar.xz" || die
+
+	if use test; then
+		einfo "Unpacking parts of ${LIBCXX_P}.tar.xz ..."
+		tar -xf "${DISTDIR}/${LIBCXX_P}.tar.xz" \
+			"${LIBCXX_P}"/{include,utils/libcxx} || die
+		mv "${LIBCXX_P}" libcxx || die
+	fi
+}
+
+multilib_src_configure() {
+	local libdir=$(get_libdir)
+
+	local mycmakeargs=(
+		-DLLVM_LIBDIR_SUFFIX=${libdir#lib}
+		-DLIBUNWIND_ENABLE_ASSERTIONS=$(usex debug)
+		-DLIBUNWIND_ENABLE_STATIC=$(usex static-libs)
+		-DLLVM_INCLUDE_TESTS=$(usex test)
+
+		# support non-native unwinding; given it's small enough,
+		# enable it unconditionally
+		-DLIBUNWIND_ENABLE_CROSS_UNWINDING=ON
+	)
+	if use test; then
+		mycmakeargs+=(
+			-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+			-DLLVM_LIT_ARGS="-vv"
+			-DLIBUNWIND_LIBCXX_PATH="${WORKDIR}"/libcxx
+		)
+	fi
+
+	cmake-utils_src_configure
+}
+
+multilib_src_test() {
+	cmake-utils_src_make check-unwind
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+
+	# install headers like sys-libs/libunwind
+	doheader "${S}"/include/*.h
+}