sys-fs/unionfs-fuse: 2.1 + EAPI 7 + tests + sync 9999

Signed-off-by: Sebastian Pipping <sping@gentoo.org>
Package-Manager: Portage-2.3.98, Repoman-2.3.22

3 files changed, 69 insertions, 7 deletions

diff --git a/sys-fs/unionfs-fuse/Manifest b/sys-fs/unionfs-fuse/Manifest
index 560a687b4459..0b0a749a3fb7 100644
--- a/sys-fs/unionfs-fuse/Manifest
+++ b/sys-fs/unionfs-fuse/Manifest
@@ -1,2 +1,3 @@
 DIST unionfs-fuse-1.0.tar.gz 48149 BLAKE2B d1ef74980158f4710f5b545c3e98abd27eb4eb610cbe141fa1befaa2a0efc3cce3cead1a405ecdea7dd0f02fab2d2f030d96a7b1d5068a1cd5de4e2f5bfe3aec SHA512 805151acaeae8526fba430701a1690f6eb0ad8331a9e730095ee538dc2b148d02fe996a63e8a7f6471d1ef622cc5c03d82bd2b2faad1ebe3b614ec343c2f55de
 DIST unionfs-fuse-2.0.tar.gz 46537 BLAKE2B 2f5a0da5adb15c408e7b9d0c3658e389a1aea4a9a5f2f3809fc724af43cf2a4b309e4220e46647e3f3fc9b19d48c8d62692e190cf8536182abfe551bfacfcc24 SHA512 5b60204632f498931fff7671cc9f40b1800d34cb8c0d0de0773626e2653eb0a36647566c92c1d0cf79543e01b934602ef5603a06508407f352e48ef27a7ee758
+DIST unionfs-fuse-2.1.tar.gz 47917 BLAKE2B c76edbcbff98db28092f61facbdf443eda12ea97770126feac3d590e0f85e51df84308d0eeeebd96e5bafd126b472b0ded6a2ead72cac0fab3614e3cc04730dd SHA512 851e378f8c189d8a84d2a0cf47ce8f1e9cdda5e789a8c0c97aac6e0757c2f6480ca4d931a525bb94cec4af11789073ccda44ad01d7ed02de1c29ded72f578aa0
diff --git a/sys-fs/unionfs-fuse/unionfs-fuse-2.1.ebuild b/sys-fs/unionfs-fuse/unionfs-fuse-2.1.ebuild
new file mode 100644
index 000000000000..2c3037f0258e
--- /dev/null
+++ b/sys-fs/unionfs-fuse/unionfs-fuse-2.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1
+
+DESCRIPTION="Self-syncing tree-merging file system based on FUSE"
+HOMEPAGE="https://github.com/rpodgorny/unionfs-fuse"
+SRC_URI="https://github.com/rpodgorny/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-fs/fuse:0"
+DEPEND="${RDEPEND}
+	test? (
+		$(python_gen_any_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+}
+
+src_test() {
+	addwrite /dev/fuse
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
diff --git a/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild b/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild
index 76d6d822dd89..914a41411a91 100644
--- a/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild
+++ b/sys-fs/unionfs-fuse/unionfs-fuse-9999.ebuild
@@ -1,23 +1,42 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="6"
+EAPI="7"
 
-inherit git-r3
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 git-r3
 
 DESCRIPTION="Self-syncing tree-merging file system based on FUSE"
-
 HOMEPAGE="https://github.com/rpodgorny/unionfs-fuse"
 EGIT_REPO_URI="https://github.com/rpodgorny/unionfs-fuse.git"
 
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS=""
-IUSE=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-fs/fuse:0"
+DEPEND="${RDEPEND}
+	test? (
+		$(python_gen_any_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+	)
+"
 
-DEPEND="sys-fs/fuse:0"
-RDEPEND="${DEPEND}"
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
 
 src_install() {
 	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
 }
+
+src_test() {
+	addwrite /dev/fuse
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}