sys-fs/lxcfs: add 6.0.0

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 82 insertions, 0 deletions

diff --git a/sys-fs/lxcfs/Manifest b/sys-fs/lxcfs/Manifest
index 702f72006a70..ddfde18b76ed 100644
--- a/sys-fs/lxcfs/Manifest
+++ b/sys-fs/lxcfs/Manifest
@@ -1,2 +1,4 @@
 DIST lxcfs-5.0.4.tar.gz 104249 BLAKE2B 83a7b861136c34da8a24dd525fd0767193f2bbd92b40e3b9fd5e42d7645465411792e65e95797ab13b33330299d12b19bdd5786352875ed88ac0097b72b711a9 SHA512 b404045dbabe23e1d1f1d74c1648d2596bb70aaa9f9e46f9f5635b0a02d0c451f68b2559920bbefc5b889e908cf1da0a33c148b26bdce3e45c3d0cbdff710604
 DIST lxcfs-5.0.4.tar.gz.asc 833 BLAKE2B aff883d24b374b296ea3678670e5e82c723fd0e35cfd7fed555aabbd811a104becc0b741331b4aa4a5129c9fff4dc88c6a86e7d64a89fe86aea81718f5d432dd SHA512 56b639597dbaf3008fe030147ea37192bd465c467a79e11ce139bcaa6bca1625b4bb9c4eda6ea1877446769f0fad9b4c5a3513d4f4415b841db96d5da8325ddc
+DIST lxcfs-6.0.0.tar.gz 103369 BLAKE2B 9261ab7d932d315117361a548372930c37129d3c1b3d5aa00bbce6bac923a94e69b0fa223632b1ef22938b047e6ebec7416cf187e76c72680e4d86db173d199a SHA512 fab5569da66a742a51c9f249c3f0256d1ea17dc0a1e7c2d5563d993cd0d236ae664a53809e65fbec2467f5d255dfd867327a28d9465ffe180d240ca131331c59
+DIST lxcfs-6.0.0.tar.gz.asc 833 BLAKE2B cfc6a8e574aeb1c9e3fec322df5254c431878f0109ea43ee1069e8213467ed16fedbe137befa47a2557d8c055591a9f00c99f221d482f715d5cdc678d79c5fa5 SHA512 019178b37045c3c2c4d8be7c417abb4ed8b7ce011bce805b220f6213d7940f164c45632a5ce02ea29451c8148f782d6b7ece7699da7f3ef7306bd437d40fe537
diff --git a/sys-fs/lxcfs/lxcfs-6.0.0.ebuild b/sys-fs/lxcfs/lxcfs-6.0.0.ebuild
new file mode 100644
index 000000000000..c0e7a84ec0f5
--- /dev/null
+++ b/sys-fs/lxcfs/lxcfs-6.0.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake meson python-any-r1 systemd verify-sig
+
+DESCRIPTION="FUSE filesystem for LXC"
+HOMEPAGE="https://linuxcontainers.org/lxcfs/introduction/ https://github.com/lxc/lxcfs/"
+SRC_URI="https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz
+	verify-sig? ( https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz.asc )"
+
+LICENSE="Apache-2.0 LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc test"
+
+DEPEND="sys-fs/fuse:3"
+RDEPEND="${DEPEND}"
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	doc? ( sys-apps/help2man )
+	verify-sig? ( sec-keys/openpgp-keys-linuxcontainers )"
+
+# Needs some black magic to work inside container/chroot.
+RESTRICT="test"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/linuxcontainers.asc
+
+python_check_deps() {
+	python_has_version -b "dev-python/jinja[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# Fix python shebangs for python-exec[-native-symlinks], #851480
+	local shebangs=($(grep -rl "#!/usr/bin/env python3" || die))
+	python_fix_shebang -q ${shebangs[*]}
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}/var"
+
+		$(meson_use doc docs)
+		$(meson_use test tests)
+
+		-Dfuse-version=3
+		-Dinit-script=""
+		-Dwith-init-script=""
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}"/tests || die "failed to change into tests/ directory."
+	./main.sh || die
+}
+
+src_install() {
+	meson_src_install
+
+	newconfd "${FILESDIR}"/lxcfs-5.0.2.confd lxcfs
+	newinitd "${FILESDIR}"/lxcfs-5.0.2.initd lxcfs
+
+	# Provide our own service file (copy of upstream) due to paths being different from upstream,
+	# #728470
+	systemd_newunit "${FILESDIR}"/lxcfs-5.0.2.service lxcfs.service
+}