sys-boot/plymouth: meson port, add: 24.004.60 & 9999

Signed-off-by: DerpDays <34582078+DerpDays@users.noreply.github.com>
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

5 files changed, 189 insertions, 51 deletions

diff --git a/sys-boot/plymouth/Manifest b/sys-boot/plymouth/Manifest
index 6eb0a48b567b..fe4704d58a05 100644
--- a/sys-boot/plymouth/Manifest
+++ b/sys-boot/plymouth/Manifest
@@ -1,2 +1,3 @@
 DIST gentoo-logo.png 14501 BLAKE2B e7236c16b96a2d35a6f062b89bc0a6c6fc696a803b7da734ff9ae255fcd65e549d9bc3d510c283e235a770f42edcbdffc1d5cc4c2fcdec9cc931eb0acf504859 SHA512 059a555931b6d2a910bcd887f5ea0cc17c6edf2d2d45c03a1fec1bdda0138ba6bca6bdf90a65c6520a3f8f1b51ecf6f7956098f45ed6c1276f29c835e729163c
 DIST plymouth-22.02.122.tar.xz 1183608 BLAKE2B 8bb1362fcaa7d4c0fb1b69729a8a681d992a5d2abc07644d3be5cc0b19df2cac83df031165a65fa06f95042f619b9f4b7a7e1f3816528f6623473a2b1303e1be SHA512 9f2f5a7121b431f16561d6b5f31177ff06cf1e6bdffaa68c1fe08aa3c765a96dee745824aae8eaac9a0b4a08f0a17a9ae79a82bd0826fcc3fe14d8553635f817
+DIST plymouth-24.004.60.tar.xz 1059904 BLAKE2B 092abeafb7a31d33be8c73160e87a681bcc8bdf72e79c07cca4152fc1a262dc857af5e8f31f32c850332ff6804fa5a87e05fd35b6490fa26153451f38d994434 SHA512 6c66ae81498afea75a9cc1c19ec82b26210a3bd463f14b8ea7c1cd1e327069ef32f752f4ee5236070825ee42599cf05f14271000523bdbae656a200d2e60d341
diff --git a/sys-boot/plymouth/metadata.xml b/sys-boot/plymouth/metadata.xml
index 5900b9002bfe..19cbc17ef98f 100644
--- a/sys-boot/plymouth/metadata.xml
+++ b/sys-boot/plymouth/metadata.xml
@@ -12,6 +12,8 @@
 			text prompts, e.g. for password</flag>
 		<flag name="split-usr">Enable this if /bin and /usr/bin are separate
 			directories</flag>
+		<flag name="freetype">Build with freetype support (if enabled, used for
+			encryption prompts)</flag>
 	</use>
 	<longdescription lang="en">
 		Plymouth is an application that runs very early in the boot process
diff --git a/sys-boot/plymouth/plymouth-22.02.122-r1.ebuild b/sys-boot/plymouth/plymouth-22.02.122-r2.ebuild
index 69c07f646c9c..17cfe3a4ca4c 100644
--- a/sys-boot/plymouth/plymouth-22.02.122-r1.ebuild
+++ b/sys-boot/plymouth/plymouth-22.02.122-r2.ebuild
@@ -28,7 +28,7 @@ CDEPEND="
 	drm? ( x11-libs/libdrm )
 	gtk? (
 		dev-libs/glib:2
-		>=x11-libs/gtk+-3.14:3
+		>=x11-libs/gtk+-3.14:3[X]
 		x11-libs/cairo
 	)
 	pango? ( >=x11-libs/pango-1.21 )
diff --git a/sys-boot/plymouth/plymouth-24.004.60.ebuild b/sys-boot/plymouth/plymouth-24.004.60.ebuild
new file mode 100644
index 000000000000..2f4af0114ed3
--- /dev/null
+++ b/sys-boot/plymouth/plymouth-24.004.60.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson readme.gentoo-r1 flag-o-matic
+
+SRC_URI="https://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/plymouth/plymouth"
+else
+	SRC_URI="${SRC_URI} https://www.freedesktop.org/software/plymouth/releases/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="Graphical boot animation (splash) and logger"
+HOMEPAGE="https://cgit.freedesktop.org/plymouth/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="debug +drm +gtk +pango selinux freetype +split-usr +udev doc systemd"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-xsl-stylesheets
+		dev-libs/libxslt
+	)
+"
+
+COMMON_DEPEND="
+	dev-libs/libevdev
+	>=media-libs/libpng-1.2.16:=
+	x11-libs/libxkbcommon
+	x11-misc/xkeyboard-config
+	drm? ( x11-libs/libdrm )
+	freetype? ( media-libs/freetype:2 )
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/cairo
+		>=x11-libs/gtk+-3.14:3[X]
+	)
+	pango? (
+		x11-libs/cairo
+		>=x11-libs/pango-1.21
+	)
+	systemd? ( sys-apps/systemd )
+	udev? ( virtual/libudev )
+"
+
+DEPEND="${COMMON_DEPEND}
+	elibc_musl? ( sys-libs/rpmatch-standalone )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	selinux? ( sec-policy/selinux-plymouthd )
+	udev? ( virtual/udev )
+"
+
+DOC_CONTENTS="
+	Follow the following instructions to set up Plymouth:\n
+	https://wiki.gentoo.org/wiki/Plymouth#Configuration
+"
+
+src_prepare() {
+	use elibc_musl && append-ldflags -lrpmatch
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		$(meson_feature gtk)
+		$(meson_feature freetype)
+		$(meson_feature pango)
+		$(meson_feature udev)
+		$(meson_use drm)
+		$(meson_use systemd systemd-integration)
+		$(meson_use doc docs)
+		$(meson_use debug tracing)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	insinto /usr/share/plymouth
+
+	newins "${DISTDIR}"/gentoo-logo.png bizcom.png
+	# fix broken symlink
+	dosym ../../bizcom.png /usr/share/plymouth/themes/spinfinity/header-image.png
+
+	if use split-usr; then
+		# Install compatibility symlinks as some rdeps hardcode the paths
+		dosym ../usr/bin/plymouth /bin/plymouth
+		dosym ../usr/sbin/plymouth-set-default-theme /sbin/plymouth-set-default-theme
+		dosym ../usr/sbin/plymouthd /sbin/plymouthd
+	fi
+
+	# the file /var/spool/plymouth/boot.log is linked to the boot log after
+	# booting when there are errors, there is no runtime check to create this
+	# directory (the file is directly linked using unistd `link`) meaning there
+	# may be missing logs or unexpected behaviour if it is not kept.
+	keepdir /var/spool/plymouth
+	# /var/lib/plymouth is created at runtime, and is used to store boot/shutdown
+	# durations, it doesn't need to be created at build.
+	rm -r "${ED}"/var/lib || die
+	# /run/plymouth is also created at runtime
+	rm -r "${ED}"/run || die
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+	if ! has_version "sys-kernel/dracut"; then
+		ewarn "dracut is not installed, if you wish to have an initramfs with"
+		ewarn "plymouth support, you can emerge 'sys-kernel/dracut' otherwise"
+		ewarn "you can look at the plymouth wiki for other methods:"
+		ewarn "https://wiki.gentoo.org/wiki/Plymouth#Building_Initramfs"
+	fi
+}
diff --git a/sys-boot/plymouth/plymouth-9999.ebuild b/sys-boot/plymouth/plymouth-9999.ebuild
index 80e29469a5bb..7e288731c8cb 100644
--- a/sys-boot/plymouth/plymouth-9999.ebuild
+++ b/sys-boot/plymouth/plymouth-9999.ebuild
@@ -1,9 +1,10 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
+
+inherit meson readme.gentoo-r1 flag-o-matic
 
-inherit flag-o-matic
 SRC_URI="https://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"
 
 if [[ ${PV} == 9999 ]]; then
@@ -11,39 +12,51 @@ if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://gitlab.freedesktop.org/plymouth/plymouth"
 else
 	SRC_URI="${SRC_URI} https://www.freedesktop.org/software/plymouth/releases/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
 fi
 
-inherit autotools readme.gentoo-r1 systemd
-
 DESCRIPTION="Graphical boot animation (splash) and logger"
 HOMEPAGE="https://gitlab.freedesktop.org/plymouth/plymouth"
 
-LICENSE="GPL-2"
+LICENSE="GPL-2+"
 SLOT="0"
-IUSE="debug +drm +gtk +pango selinux +split-usr static-libs +udev"
+IUSE="debug +drm +gtk +pango selinux freetype +split-usr +udev doc systemd"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-xsl-stylesheets
+		dev-libs/libxslt
+	)
+"
 
-CDEPEND="
+COMMON_DEPEND="
+	dev-libs/libevdev
 	>=media-libs/libpng-1.2.16:=
+	x11-libs/libxkbcommon
+	x11-misc/xkeyboard-config
 	drm? ( x11-libs/libdrm )
+	freetype? ( media-libs/freetype:2 )
 	gtk? (
 		dev-libs/glib:2
-		>=x11-libs/gtk+-3.14:3
 		x11-libs/cairo
+		>=x11-libs/gtk+-3.14:3[X]
 	)
-	pango? ( >=x11-libs/pango-1.21 )
+	pango? (
+		x11-libs/cairo
+		>=x11-libs/pango-1.21
+	)
+	systemd? ( sys-apps/systemd )
+	udev? ( virtual/libudev )
 "
-DEPEND="${CDEPEND}
+
+DEPEND="${COMMON_DEPEND}
 	elibc_musl? ( sys-libs/rpmatch-standalone )
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
-	virtual/pkgconfig
 "
-# Block due bug #383067
-RDEPEND="${CDEPEND}
+
+RDEPEND="${COMMON_DEPEND}
 	selinux? ( sec-policy/selinux-plymouthd )
 	udev? ( virtual/udev )
-	!<sys-kernel/dracut-0.37-r3
 "
 
 DOC_CONTENTS="
@@ -51,63 +64,61 @@ DOC_CONTENTS="
 	https://wiki.gentoo.org/wiki/Plymouth#Configuration
 "
 
-PATCHES=(
-	"${FILESDIR}"/0.9.3-glibc-sysmacros.patch
-)
-
 src_prepare() {
 	use elibc_musl && append-ldflags -lrpmatch
 	default
-	eautoreconf
 }
 
 src_configure() {
-	local myconf=(
-		--with-system-root-install=no
-		--localstatedir=/var
-		--without-rhgb-compat-link
-		--enable-documentation
-		--enable-systemd-integration
-		--with-systemdunitdir="$(systemd_get_systemunitdir)"
-		$(use_enable !static-libs shared)
-		$(use_enable static-libs static)
-		$(use_enable debug tracing)
-		$(use_enable drm)
-		$(use_enable gtk)
-		$(use_enable pango)
-		$(use_with udev)
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		$(meson_feature gtk)
+		$(meson_feature freetype)
+		$(meson_feature pango)
+		$(meson_feature udev)
+		$(meson_use drm)
+		$(meson_use systemd systemd-integration)
+		$(meson_use doc docs)
+		$(meson_use debug tracing)
 	)
-	econf "${myconf[@]}"
+	meson_src_configure
 }
 
 src_install() {
-	default
-
+	meson_src_install
 	insinto /usr/share/plymouth
+
 	newins "${DISTDIR}"/gentoo-logo.png bizcom.png
+	# fix broken symlink
+	dosym ../../bizcom.png /usr/share/plymouth/themes/spinfinity/header-image.png
 
-	if use split-usr ; then
+	if use split-usr; then
 		# Install compatibility symlinks as some rdeps hardcode the paths
 		dosym ../usr/bin/plymouth /bin/plymouth
 		dosym ../usr/sbin/plymouth-set-default-theme /sbin/plymouth-set-default-theme
 		dosym ../usr/sbin/plymouthd /sbin/plymouthd
 	fi
 
-	readme.gentoo_create_doc
-
-	# looks like make install create /var/run/plymouth
-	# this is not needed for systemd, same should hold for openrc
-	# so remove
-	rm -rf "${D}"/var/run
+	# the file /var/spool/plymouth/boot.log is linked to the boot log after
+	# booting when there are errors, there is no runtime check to create this
+	# directory (the file is directly linked using unistd `link`) meaning there
+	# may be missing logs or unexpected behaviour if it is not kept.
+	keepdir /var/spool/plymouth
+	# /var/lib/plymouth is created at runtime, and is used to store boot/shutdown
+	# durations, it doesn't need to be created at build.
+	rm -r "${ED}"/var/lib || die
+	# /run/plymouth is also created at runtime
+	rm -r "${ED}"/run || die
 
-	# fix broken symlink
-	dosym ../../bizcom.png /usr/share/plymouth/themes/spinfinity/header-image.png
+	readme.gentoo_create_doc
 }
 
 pkg_postinst() {
 	readme.gentoo_print_elog
 	if ! has_version "sys-kernel/dracut"; then
-		ewarn "If you want initramfs builder with plymouth support, please emerge"
-		ewarn "sys-kernel/dracut."
+		ewarn "dracut is not installed, if you wish to have an initramfs with"
+		ewarn "plymouth support, you can emerge 'sys-kernel/dracut' otherwise"
+		ewarn "you can look at the plymouth wiki for other methods:"
+		ewarn "https://wiki.gentoo.org/wiki/Plymouth#Building_Initramfs"
 	fi
 }