sys-apps/miller: bump to version 5.2.2

Adding myself and proxy maintainer project as maintainers to signal
proxy maintainers project leads. Cleanup per guidance from mgorny.

Closes: https://github.com/gentoo/gentoo/pull/5446
Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 47 insertions, 0 deletions

diff --git a/sys-apps/miller/miller-5.2.2.ebuild b/sys-apps/miller/miller-5.2.2.ebuild
new file mode 100644
index 000000000000..7d27a1bf9b8d
--- /dev/null
+++ b/sys-apps/miller/miller-5.2.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="A tool like sed, awk, cut, join, and sort for name-indexed data (CSV, JSON, ..)"
+HOMEPAGE="http://johnkerl.org/miller"
+SRC_URI="https://github.com/johnkerl/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc test"
+
+DEPEND="sys-devel/flex"
+
+src_prepare() {
+	default
+
+	# respect flags
+	find -type f -name "Makefile.am" -exec sed -i -r -e '/.*FLAGS[^=]*=/ s:(-g|-pg|-O[0-9]) ::g' -- {} \; || die
+
+	# disable docs rebuilding as they're shipped prebuilt
+	sed -e '/SUBDIRS[^=]*=/ s:doc::g' -i -- Makefile.am || die
+
+	# disable building tests automagically
+	if ! use test; then
+		sed -e '/SUBDIRS[^=]*=/ s:[^ ]*_test::g' -i -- c/Makefile.am || die
+	fi
+
+	eautoreconf
+}
+
+src_test() {
+	emake -C c/reg_test
+	emake -C c/unit_test
+}
+
+src_install() {
+	local HTML_DOCS=( $(usev doc) )
+
+	default
+
+	doman 'doc/mlr.1'
+}