sci-electronics/fritzing: Install parts library with 0.9.2b #548624

Gentoo-Bug: https://bugs.gentoo.org/548624

- Install readme.md
- Fix missing Intel bin icon
https://github.com/fritzing/fritzing-parts/commit/716560e9

- Use Bash extended test command
- Add slot-operator to boost
- Update to EAPI 6
- Declare lang
- Replace LINGUAS with L10N
Suggested-by: David Seifert <soap@gentoo.org>

- Update LICENSE
- Add missing '|| die's
- Remove unnecessary edos2unix
https://github.com/gentoo/gentoo/pull/1744
Suggested-by: Gokturk Yuksek <gokturk@gentoo.org>

- Ensure quazip built with Qt5
Gentoo-Bug: https://bugs.gentoo.org/562490
Suggested-by: Carl Michal <michal@physics.ubc.ca>
Closes: https://github.com/gentoo/gentoo/pull/1744

Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 77 insertions, 0 deletions

diff --git a/sci-electronics/fritzing/fritzing-0.9.2b-r1.ebuild b/sci-electronics/fritzing/fritzing-0.9.2b-r1.ebuild
new file mode 100644
index 000000000000..83fd5c314734
--- /dev/null
+++ b/sci-electronics/fritzing/fritzing-0.9.2b-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PARTS_P="${PN}-parts-${PV}"
+
+inherit qmake-utils
+
+DESCRIPTION="Electronic Design Automation"
+HOMEPAGE="http://fritzing.org/"
+SRC_URI="https://github.com/fritzing/fritzing-app/archive/${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/fritzing/fritzing-parts/archive/${PV}.tar.gz -> ${PARTS_P}.tar.gz"
+
+LICENSE="CC-BY-SA-3.0 GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtserialport:5
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-libs/quazip[qt5]"
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.40:="
+
+S="${WORKDIR}/${PN}-app-${PV}"
+
+DOCS="readme.md"
+
+src_prepare() {
+	local lang translations=
+
+	# Get a rid of the bundled libs
+	# Bug 412555 and
+	# https://code.google.com/p/fritzing/issues/detail?id=1898
+	rm -rf src/lib/quazip/ pri/quazip.pri src/lib/boost* || die
+
+	# Fritzing doesn't need zlib
+	sed -i -e 's:LIBS += -lz::' -e 's:-lminizip::' phoenix.pro || die
+
+	# Somewhat evil but IMHO the best solution
+	for lang in $L10N; do
+		lang=${lang/linguas_}
+		[[ -f "translations/${PN}_${lang}.qm" ]] && translations+=" translations/${PN}_${lang}.qm"
+	done
+	if [[ -n "${translations}" ]]; then
+		sed -i -e "s:\(translations.extra =\) .*:\1	cp -p ${translations} \$(INSTALL_ROOT)\$\$PKGDATADIR/translations\r:" phoenix.pro || die
+	else
+		sed -i -e "s:translations.extra = .*:\r:" phoenix.pro || die
+	fi
+
+	# Fix missing Intel bin icon
+	# https://github.com/fritzing/fritzing-parts/commit/716560e9
+	sed -i -e 's:Intel.png:intel.png:' bins/more/intel.fzb || die
+
+	default
+}
+
+src_configure() {
+	eqmake5 DEFINES=QUAZIP_INSTALLED phoenix.pro
+}
+
+src_install() {
+	INSTALL_ROOT="${D}" default
+
+	insinto /usr/share/fritzing/parts
+	doins -r "${WORKDIR}/${PARTS_P}"/*
+}