net-news/liferea: add 1.14_rc2

Signed-off-by: Yuri Konotopov <ykonotopov@gnome.org>
Closes: https://github.com/gentoo/gentoo/pull/28026
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/net-news/liferea/Manifest b/net-news/liferea/Manifest
index 06831e530bc0..efdb671607a1 100644
--- a/net-news/liferea/Manifest
+++ b/net-news/liferea/Manifest
@@ -1 +1,2 @@
 DIST liferea-1.12.9.tar.bz2 1496593 BLAKE2B a0887a7b04c47a69166396f06305342232b16eefba04df1a0cda7c9d84880e025d73786a55aaa528a143fccef213fa2de9474fb6fab3f301e54a12dba4a705f1 SHA512 09156e0e5e4342741b6290be17ee94a3204d431c687c17688e23067d151d36a178193f5cf01da222974810a48626c877b0cf917fbdd9ecb6e81254e85750be9b
+DIST liferea-1.14-RC2.tar.bz2 1737026 BLAKE2B a47b9e675c429ab38d3cf451ee1b42d17819ce95926d631ead3fbdfdf510b5ee6c387c7b774b4966a7608ded738a81c163b0d032ec8e18a87c4a52e9b18b3413 SHA512 15c4bd6e46ae96ea5fda36bcb055d7eb674f5b5be07c1ae3a9846694b3345518d00ce80f2af740f317ee68a9703673a8dbba4ee560bda5d58276f4d498c83b59
diff --git a/net-news/liferea/liferea-1.14_rc2.ebuild b/net-news/liferea/liferea-1.14_rc2.ebuild
new file mode 100644
index 000000000000..1bfd9f30210a
--- /dev/null
+++ b/net-news/liferea/liferea-1.14_rc2.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+MY_PV="${PV/_/-}"
+MY_PV="${MY_PV^^}"
+MY_P="${PN}-${MY_PV}"
+
+inherit autotools gnome2-utils optfeature python-single-r1 xdg
+
+DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo feeds"
+HOMEPAGE="https://lzone.de/liferea/"
+SRC_URI="https://github.com/lwindolf/${PN}/releases/download/v${MY_PV}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	dev-libs/json-glib
+	dev-libs/libpeas[gtk,python,${PYTHON_SINGLE_USEDEP}]
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	gnome-base/gsettings-desktop-schemas
+	net-libs/libsoup:2.4
+	net-libs/webkit-gtk:4
+	x11-libs/gtk+:3
+	x11-libs/pango"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-util/intltool
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	xdg_src_prepare
+
+	sed -i -e 's#$(datadir)/appdata#$(datadir)/metainfo#g' \
+		Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf --disable-static
+}
+
+src_compile() {
+	# Workaround crash in libwebkit2gtk-4.0.so
+	# https://bugs.gentoo.org/704594
+	WEBKIT_DISABLE_COMPOSITING_MODE=1 \
+		default
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	optfeature "Libsecret Support plugin" app-crypt/libsecret[introspection]
+	optfeature "Tray Icon (GNOME Classic) plugin" "dev-python/pycairo x11-libs/gdk-pixbuf[introspection]"
+	optfeature "Media Player plugin" media-libs/gstreamer[introspection]
+	optfeature "monitoring network status" net-misc/networkmanager
+	optfeature "Popup Notifications plugin" x11-libs/libnotify[introspection]
+}