net-misc/youtube-dl: Version 2020.06.16.1

Package-Manager: Portage-2.3.101, Repoman-2.3.22
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index c3679823ba54..3bacf14482a0 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1,2 +1,3 @@
 DIST youtube-dl-2020.06.06.tar.gz 3176995 BLAKE2B 0971a8f82eedf3dc6a635b90318586988ffc8a8219386e0eda8ca020fb9981ceabb4b708c0d90c38f5eab2c17daa98d73cead473e33a1ed27b726a087d9a57f7 SHA512 b3c910f8b26a11e225cfdebc3612e04010e1af027bc48b88f0b8bd36ba83f10eaed05375cbc833b421da9b377152722aa74ab936ed238957165a6b5f0149589b
+DIST youtube-dl-2020.06.16.1.tar.gz 3177873 BLAKE2B 8bf2df25b416c4a48b2b4a14466f15f99b1bbe0b4900c18e30bc3edab66a54b036f95025218cb584f820f3c45b2ab2e805f21e2d6548078d49c6a122fb52716d SHA512 2f0c01cd1a52293afd8c4fddc20b6f7baca94903fbe852769ad1d25740bd87e38d42ee4a275c2e3d611c639c432f6245d27f361471c6b566da03677384a04e54
 DIST youtube-dl-2020.06.16.tar.gz 3178801 BLAKE2B e0c724c8eb239622efa0528d37ef028d81eebea1ef601512166e48afa9edc4710c9f2f641db050afc34a82b0ed305fdf3ffe04d51f672d6e334ef83d3120b7d0 SHA512 83689b98b74f45bf13049eaf4c109081ef783d7978085b58b76a761a74facc1f4f19a3cac8542960359bf961fd4543c6ab2c4a130316fe4285b2d2d5855ed099
diff --git a/net-misc/youtube-dl/youtube-dl-2020.06.16.1.ebuild b/net-misc/youtube-dl/youtube-dl-2020.06.16.1.ebuild
new file mode 100644
index 000000000000..27edc068096a
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.06.16.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python3_{6,7,8})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+RDEPEND="
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need ffmpeg (media-video/ffmpeg)."
+	elog "On some sites - most notably YouTube - videos can be retrieved in"
+	elog "a higher quality format without sound. ${PN} will detect whether"
+	elog "ffmpeg is present and automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}