net-misc/freerdp: add slots

Signed-off-by: Mike Gilbert <floppym@gentoo.org>

5 files changed, 203 insertions, 29 deletions

diff --git a/net-misc/freerdp/freerdp-2.11.5-r10.ebuild b/net-misc/freerdp/freerdp-2.11.5-r10.ebuild
new file mode 100644
index 000000000000..fdad406de1cd
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.11.5-r10.ebuild
@@ -0,0 +1,150 @@
+# Copyright 2011-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+	case ${PV} in
+		2.*) EGIT_BRANCH="stable-2.0";;
+	esac
+else
+	MY_P=${P/_/-}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="https://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="2"
+IUSE="alsa cpu_flags_arm_neon client cups debug doc +ffmpeg gstreamer icu jpeg kerberos openh264 pulseaudio server smartcard systemd test tools usb valgrind wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) )
+"
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	usb? (
+		virtual/libudev:0=
+		sys-apps/util-linux:0=
+		dev-libs/dbus-glib:0=
+		virtual/libusb:1=
+	)
+	X? (
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		xinerama? ( x11-libs/libXinerama )
+		xv? ( x11-libs/libXv )
+	)
+	ffmpeg? ( media-video/ffmpeg:0= )
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	icu? ( dev-libs/icu:0= )
+	jpeg? ( media-libs/libjpeg-turbo:0= )
+	kerberos? ( virtual/krb5 )
+	openh264? ( media-libs/openh264:0= )
+	pulseaudio? ( media-libs/libpulse )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	valgrind? ( dev-debug/valgrind )
+"
+RDEPEND="${COMMON_DEPEND}
+	!net-misc/freerdp:0
+	client? ( !net-misc/freerdp:3[client] )
+	server? ( !net-misc/freerdp:3[server] )
+	tools? ( !net-misc/freerdp:3[tools] )
+"
+
+PATCHES=(
+	"${FILESDIR}/freerdp-2.11.2-clang.patch"
+	"${FILESDIR}/freerdp-2.11-Revert-codec-encode-messages-considering-endianness.patch"
+)
+
+src_configure() {
+	# bug #881695
+	filter-lto
+
+	local mycmakeargs=(
+		-Wno-dev
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHANNEL_URBDRC=$(usex usb ON OFF)
+		-DWITH_ALSA=$(usex alsa ON OFF)
+		-DWITH_CCACHE=OFF
+		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_CLIENT=$(usex client ON OFF)
+		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
+		-DWITH_MANPAGES=$(usex doc ON OFF)
+		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_SWSCALE=$(usex ffmpeg ON OFF)
+		-DWITH_CAIRO=$(usex ffmpeg OFF ON)
+		-DWITH_DSP_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer ON OFF)
+		-DWITH_ICU=$(usex icu ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_GSSAPI=$(usex kerberos ON OFF)
+		-DWITH_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DWITH_OPENH264=$(usex openh264 ON OFF)
+		-DWITH_OSS=OFF
+		-DWITH_PULSE=$(usex pulseaudio ON OFF)
+		-DWITH_SERVER=$(usex server ON OFF)
+		-DWITH_PCSC=$(usex smartcard ON OFF)
+		-DWITH_LIBSYSTEMD=$(usex systemd ON OFF)
+		-DWITH_VALGRIND_MEMCHECK=$(usex valgrind ON OFF)
+		-DWITH_X11=$(usex X ON OFF)
+		-DWITH_XINERAMA=$(usex xinerama ON OFF)
+		-DWITH_XV=$(usex xv ON OFF)
+		-DWITH_WAYLAND=$(usex wayland ON OFF)
+		-DWITH_WINPR_TOOLS=$(usex tools ON OFF)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local myctestargs=()
+	use elibc_musl && myctestargs+=( -E TestBacktrace )
+	cmake_src_test
+}
diff --git a/net-misc/freerdp/freerdp-2.9999.ebuild b/net-misc/freerdp/freerdp-2.9999.ebuild
index 6e2277b4bffe..9cabbcb2d8b9 100644
--- a/net-misc/freerdp/freerdp-2.9999.ebuild
+++ b/net-misc/freerdp/freerdp-2.9999.ebuild
@@ -22,11 +22,19 @@ DESCRIPTION="Free implementation of the Remote Desktop Protocol"
 HOMEPAGE="https://www.freerdp.com/"
 
 LICENSE="Apache-2.0"
-SLOT="0/2"
-IUSE="alsa cpu_flags_arm_neon cups debug doc +ffmpeg gstreamer icu jpeg kerberos openh264 pulseaudio server smartcard systemd test usb valgrind wayland X xinerama xv"
+SLOT="2"
+IUSE="alsa cpu_flags_arm_neon client cups debug doc +ffmpeg gstreamer icu jpeg kerberos openh264 pulseaudio server smartcard systemd test tools usb valgrind wayland X xinerama xv"
 RESTRICT="!test? ( test )"
 
-RDEPEND="
+BDEPEND="
+	virtual/pkgconfig
+	X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) )
+"
+
+COMMON_DEPEND="
 	dev-libs/openssl:0=
 	sys-libs/zlib:0
 	alsa? ( media-libs/alsa-lib )
@@ -81,16 +89,14 @@ RDEPEND="
 		x11-libs/libxkbfile
 	)
 "
-DEPEND="
-	${RDEPEND}
+DEPEND="${COMMON_DEPEND}
 	valgrind? ( dev-debug/valgrind )
 "
-BDEPEND="
-	virtual/pkgconfig
-	X? ( doc? (
-		app-text/docbook-xml-dtd:4.1.2
-		app-text/xmlto
-	) )
+RDEPEND="${COMMON_DEPEND}
+	!net-misc/freerdp:0
+	client? ( !net-misc/freerdp:3[client] )
+	server? ( !net-misc/freerdp:3[server] )
+	tools? ( !net-misc/freerdp:3[tools] )
 "
 
 src_configure() {
@@ -104,6 +110,7 @@ src_configure() {
 		-DWITH_ALSA=$(usex alsa ON OFF)
 		-DWITH_CCACHE=OFF
 		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_CLIENT=$(usex client ON OFF)
 		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
 		-DWITH_MANPAGES=$(usex doc ON OFF)
 		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
@@ -126,6 +133,7 @@ src_configure() {
 		-DWITH_XINERAMA=$(usex xinerama ON OFF)
 		-DWITH_XV=$(usex xv ON OFF)
 		-DWITH_WAYLAND=$(usex wayland ON OFF)
+		-DWITH_WINPR_TOOLS=$(usex tools ON OFF)
 	)
 	cmake_src_configure
 }
diff --git a/net-misc/freerdp/freerdp-3.4.0-r2.ebuild b/net-misc/freerdp/freerdp-3.4.0-r10.ebuild
index 82b1a427b285..81778320b41c 100644
--- a/net-misc/freerdp/freerdp-3.4.0-r2.ebuild
+++ b/net-misc/freerdp/freerdp-3.4.0-r10.ebuild
@@ -22,11 +22,16 @@ DESCRIPTION="Free implementation of the Remote Desktop Protocol"
 HOMEPAGE="https://www.freerdp.com/"
 
 LICENSE="Apache-2.0"
-SLOT="0/3"
-IUSE="aad alsa cpu_flags_arm_neon cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test usb valgrind wayland X xinerama xv"
+SLOT="3"
+IUSE="aad alsa cpu_flags_arm_neon +client cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test +tools usb valgrind wayland X xinerama xv"
 RESTRICT="!test? ( test )"
 
-RDEPEND="
+BDEPEND="
+	virtual/pkgconfig
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+"
+COMMON_DEPEND="
 	dev-libs/openssl:0=
 	sys-libs/zlib:0
 	aad? ( dev-libs/cJSON )
@@ -90,14 +95,14 @@ RDEPEND="
 		x11-libs/libxkbfile
 	)
 "
-DEPEND="
-	${RDEPEND}
+DEPEND="${COMMON_DEPEND}
 	valgrind? ( dev-debug/valgrind )
 "
-BDEPEND="
-	virtual/pkgconfig
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
+RDPEND="${COMMON_DEPEND}
+	!net-misc/freerdp:0
+	client? ( !net-misc/freerdp:2[client] )
+	server? ( !net-misc/freerdp:2[server] )
+	tools? ( !net-misc/freerdp:2[tools] )
 "
 
 src_configure() {
@@ -115,6 +120,7 @@ src_configure() {
 		-DWITH_AAD=$(usex aad ON OFF)
 		-DWITH_ALSA=$(usex alsa ON OFF)
 		-DWITH_CCACHE=OFF
+		-DWITH_CLIENT=$(usex client ON OFF)
 		-DWITH_CLIENT_SDL=$(usex sdl ON OFF)
 		-DWITH_SAMPLE=OFF
 		-DWITH_CUPS=$(usex cups ON OFF)
@@ -144,6 +150,7 @@ src_configure() {
 		-DWITH_XV=$(usex xv ON OFF)
 		-DWITH_WAYLAND=$(usex wayland ON OFF)
 		-DWITH_WEBVIEW=OFF
+		-DWITH_WINPR_TOOLS=$(usex tools ON OFF)
 	)
 	cmake_src_configure
 }
diff --git a/net-misc/freerdp/freerdp-9999.ebuild b/net-misc/freerdp/freerdp-9999.ebuild
index 82b1a427b285..81778320b41c 100644
--- a/net-misc/freerdp/freerdp-9999.ebuild
+++ b/net-misc/freerdp/freerdp-9999.ebuild
@@ -22,11 +22,16 @@ DESCRIPTION="Free implementation of the Remote Desktop Protocol"
 HOMEPAGE="https://www.freerdp.com/"
 
 LICENSE="Apache-2.0"
-SLOT="0/3"
-IUSE="aad alsa cpu_flags_arm_neon cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test usb valgrind wayland X xinerama xv"
+SLOT="3"
+IUSE="aad alsa cpu_flags_arm_neon +client cups debug +ffmpeg +fuse gstreamer +icu jpeg kerberos openh264 pulseaudio sdl server smartcard systemd test +tools usb valgrind wayland X xinerama xv"
 RESTRICT="!test? ( test )"
 
-RDEPEND="
+BDEPEND="
+	virtual/pkgconfig
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+"
+COMMON_DEPEND="
 	dev-libs/openssl:0=
 	sys-libs/zlib:0
 	aad? ( dev-libs/cJSON )
@@ -90,14 +95,14 @@ RDEPEND="
 		x11-libs/libxkbfile
 	)
 "
-DEPEND="
-	${RDEPEND}
+DEPEND="${COMMON_DEPEND}
 	valgrind? ( dev-debug/valgrind )
 "
-BDEPEND="
-	virtual/pkgconfig
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
+RDPEND="${COMMON_DEPEND}
+	!net-misc/freerdp:0
+	client? ( !net-misc/freerdp:2[client] )
+	server? ( !net-misc/freerdp:2[server] )
+	tools? ( !net-misc/freerdp:2[tools] )
 "
 
 src_configure() {
@@ -115,6 +120,7 @@ src_configure() {
 		-DWITH_AAD=$(usex aad ON OFF)
 		-DWITH_ALSA=$(usex alsa ON OFF)
 		-DWITH_CCACHE=OFF
+		-DWITH_CLIENT=$(usex client ON OFF)
 		-DWITH_CLIENT_SDL=$(usex sdl ON OFF)
 		-DWITH_SAMPLE=OFF
 		-DWITH_CUPS=$(usex cups ON OFF)
@@ -144,6 +150,7 @@ src_configure() {
 		-DWITH_XV=$(usex xv ON OFF)
 		-DWITH_WAYLAND=$(usex wayland ON OFF)
 		-DWITH_WEBVIEW=OFF
+		-DWITH_WINPR_TOOLS=$(usex tools ON OFF)
 	)
 	cmake_src_configure
 }
diff --git a/net-misc/freerdp/metadata.xml b/net-misc/freerdp/metadata.xml
index 0fc989abd6dc..f779a3f3fb62 100644
--- a/net-misc/freerdp/metadata.xml
+++ b/net-misc/freerdp/metadata.xml
@@ -7,9 +7,11 @@
 	</maintainer>
 	<use>
 		<flag name="aad">Enable login via Azure AD</flag>
+		<flag name="client">Build client binaries</flag>
 		<flag name="fuse">Clipboard with FUSE file copy support</flag>
 		<flag name="openh264">Enable H.264 support using <pkg>media-libs/openh264</pkg></flag>
 		<flag name="server">Build server binaries</flag>
+		<flag name="tools">Build tools</flag>
 	</use>
 	<upstream>
 		<remote-id type="github">FreeRDP/FreeRDP</remote-id>