net-misc/connman: add 1.42_pre20220801

Bug: https://bugs.gentoo.org/863425

Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 107 insertions, 0 deletions

diff --git a/net-misc/connman/Manifest b/net-misc/connman/Manifest
index eb7e472a6cf8..18375e3ead69 100644
--- a/net-misc/connman/Manifest
+++ b/net-misc/connman/Manifest
@@ -1 +1,2 @@
 DIST connman-1.41.tar.xz 758556 BLAKE2B 45e522d4a3a8d1a2f8eb21612d85435020f51387d4285da65da56d022df2d521f81a782af82387bdede8b71bdc591b9ffb8b79e1b1dd9d1d83ffa96eede9c1bd SHA512 b7880d908635ab9350c12e207213d20b11c1a50afcb93ae92e1fc57d4345bf792afe1a5534650e18b8cd05a3766ce9993083b2d659e49f87b867e6f2c1a83b2d
+DIST connman-363e0ed955f605fb0dc919b7ee149b6071af73ee.tar.gz 738158 BLAKE2B 05315470fe055b6b42330d3aa6e4286c551f1ce43a63e6952f0f0969d3639275eab62da0d90ff6fd756fcfca37e11d16d4ed834f0cf02e1b8cf75be742cc6a75 SHA512 e5a66134f4ee99d03aa4c77082817a4886750434e676eecb394ba1aac0475034cadec66aba27704b173151dce74e92f9e77065bcdef9576c9ed3d3cfc13a1d68
diff --git a/net-misc/connman/connman-1.42_pre20220801.ebuild b/net-misc/connman/connman-1.42_pre20220801.ebuild
new file mode 100644
index 000000000000..74a2ba49cb5d
--- /dev/null
+++ b/net-misc/connman/connman-1.42_pre20220801.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+inherit autotools systemd tmpfiles
+
+COMMIT=363e0ed955f605fb0dc919b7ee149b6071af73ee
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/connman/connman.git"
+else
+	SRC_URI="https://git.kernel.org/pub/scm/network/connman/connman.git/snapshot/connman-${COMMIT}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/connman/connman.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="bluetooth debug doc +ethernet examples iptables iwd l2tp networkmanager
++nftables ofono openconnect openvpn policykit pptp tools vpnc +wifi wireguard
+wispr"
+
+REQUIRED_USE="^^ ( iptables nftables )"
+BDEPEND="virtual/pkgconfig"
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	sys-libs/readline:0=
+	bluetooth? ( net-wireless/bluez )
+	iptables? ( >=net-firewall/iptables-1.4.8 )
+	iwd? ( net-wireless/iwd )
+	l2tp? ( net-dialup/xl2tpd )
+	nftables? (
+		>=net-libs/libnftnl-1.0.4:0=
+		>=net-libs/libmnl-1.0.0:0= )
+	ofono? ( net-misc/ofono )
+	openconnect? ( net-vpn/openconnect )
+	openvpn? ( net-vpn/openvpn )
+	policykit? ( sys-auth/polkit )
+	pptp? ( net-dialup/pptpclient )
+	vpnc? ( net-vpn/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )
+	wireguard? ( >=net-libs/libmnl-1.0.0:0= )
+	wispr? ( net-libs/gnutls )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39"
+
+PATCHES=( "${FILESDIR}/libresolv-musl-fix.patch" )
+S=${WORKDIR}/${PN}-${COMMIT}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--runstatedir=/run \
+		--with-systemdunitdir=$(systemd_get_systemunitdir) \
+		--with-tmpfilesdir="${EPREFIX}"/usr/lib/tmpfiles.d \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable debug) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable examples test) \
+		$(use_enable iwd) \
+		$(use_enable l2tp l2tp builtin) \
+		$(use_enable networkmanager nmcompat) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable pptp pptp builtin) \
+		$(use_enable tools) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable wireguard) \
+		$(use_enable wispr wispr builtin) \
+		--with-firewall=$(usex iptables "iptables" "nftables" ) \
+		--disable-iospm \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	default
+	dobin client/connmanctl
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /usr/lib/${PN}/scripts
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}
+
+pkg_postinst() {
+	tmpfiles_process connman_resolvconf.conf
+}