net-libs/gnome-online-accounts: Version bump to 3.44.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index cc037b172969..f20538847345 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1 +1,2 @@
 DIST gnome-online-accounts-3.40.1.tar.xz 861220 BLAKE2B 668af9cca8524e25b4f65f41983c527e0cac167317c28f6c451c9c9a6cea18a5774c42acd1cf80cfc707ed62524d1381039fd4f16e3e506d4789372a3db85f4f SHA512 ee7835efe6e1afd6a13f823e17eb93e4a3c55e90764f93a766270ef64f07ed18eff2fce325d8248783d7c6f1c0a7a7fe7512ebb7a8bc0a3e3b33b9037a75b088
+DIST gnome-online-accounts-3.44.0.tar.xz 859564 BLAKE2B 6131094df19d5f282491bd19a97f6e0248b10a5c4db19962a6804523101fb86d6bed7523b46cef91328e0f3c7b6496068594de0689ab1fcb63fd8fb80eece49c SHA512 e70a83b557b816dc7eb22bcd1e4a263044a16c981dfa945a529250ea76e743c9cc73f2ecd4f3006d28a4f3161c7a15dba8bd1416b413c28f4d86d0192755e809
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.44.0.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.44.0.ebuild
new file mode 100644
index 000000000000..433f793133ef
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.44.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="debug gnome +introspection kerberos +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.52:2
+	>=app-crypt/libsecret-0.5
+	>=dev-libs/json-glib-0.16
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/rest:0.7
+	>=net-libs/webkit-gtk-2.26.0:4
+	>=x11-libs/gtk+-3.19.12:3
+	x11-libs/pango
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	kerberos? (
+		app-crypt/gcr:0=[gtk]
+		app-crypt/mit-krb5
+	)
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gdbus-codegen-2.30.0
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+
+src_prepare() {
+	use vala && vala_setup
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+
+	# CONFIG_SHELL for bashisms in bug #829494, patch submitted upstream.
+	# Can be removed in future.
+	CONFIG_SHELL="${BROOT}/bin/bash" gnome2_src_configure \
+		--disable-static \
+		--enable-backend \
+		--enable-documentation \
+		--enable-exchange \
+		--enable-facebook \
+		--enable-flickr \
+		--enable-foursquare \
+		--enable-imap-smtp \
+		--enable-lastfm \
+		--enable-media-server \
+		--enable-owncloud \
+		--enable-windows-live \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable kerberos) \
+		$(use_enable kerberos fedora) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}