net-im/synapse: new package, add 1.62.0

Closes: https://bugs.gentoo.org/608510
Signed-off-by: Petr Vaněk <arkamar@atlas.cz>
Closes: https://github.com/gentoo/gentoo/pull/25776
Signed-off-by: Sam James <sam@gentoo.org>

4 files changed, 127 insertions, 0 deletions

diff --git a/net-im/synapse/Manifest b/net-im/synapse/Manifest
new file mode 100644
index 000000000000..811838f92ce3
--- /dev/null
+++ b/net-im/synapse/Manifest
@@ -0,0 +1 @@
+DIST synapse-1.62.0.gh.tar.gz 7841903 BLAKE2B f3002798a3fccd1b7fc4a1a302d12dd0940727ce8e89bcab0fdda04d498dbc9e469d21e7815db75b3593fcdfa01557e6828a39e874e946ce1b43d51cfe459ee6 SHA512 2bf9264f08fab29e8707317b69c52a4234bb25443c342ba43a27e06c506bcca1a9bdb211a99802abbca551e4f4288f68775d4629493b39d58dfcc8d8d1ca8ab8
diff --git a/net-im/synapse/files/synapse.initd b/net-im/synapse/files/synapse.initd
new file mode 100644
index 000000000000..e8e494c722c0
--- /dev/null
+++ b/net-im/synapse/files/synapse.initd
@@ -0,0 +1,10 @@
+#!/sbin/openrc-run
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+name="Matrix synapse daemon"
+description=""
+command=/usr/bin/synapse_homeserver
+command_args="--daemonize --config-path /etc/synapse/homeserver.yaml"
+pidfile=/var/lib/synapse/homeserver.pid
+start_stop_daemon_args="--user synapse --group synapse"
diff --git a/net-im/synapse/metadata.xml b/net-im/synapse/metadata.xml
new file mode 100644
index 000000000000..8ce7426a7984
--- /dev/null
+++ b/net-im/synapse/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>arkamar@atlas.cz</email>
+		<name>Petr Vaněk</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">matrix-org/synapse</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/net-im/synapse/synapse-1.62.0.ebuild b/net-im/synapse/synapse-1.62.0.ebuild
new file mode 100644
index 000000000000..d3b5db281ed0
--- /dev/null
+++ b/net-im/synapse/synapse-1.62.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..10} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=poetry
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Reference implementation of Matrix homeserver"
+HOMEPAGE="
+	https://matrix.org/
+	https://github.com/matrix-org/synapse/
+"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/matrix-org/${PN}.git"
+else
+	MY_PV="${PV/_rc/rc}"
+	SRC_URI="https://github.com/matrix-org/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-user/synapse
+	acct-group/synapse
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		dev-python/bleach[${PYTHON_USEDEP}]
+		dev-python/canonicaljson[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/frozendict[${PYTHON_USEDEP}]
+		dev-python/ijson[${PYTHON_USEDEP}]
+		>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		>=dev-python/matrix-common-1.2.1[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/netaddr[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/phonenumbers[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},webp]
+		dev-python/prometheus_client[${PYTHON_USEDEP}]
+		dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pymacaroons[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		dev-python/signedjson[${PYTHON_USEDEP}]
+		dev-python/sortedcontainers[${PYTHON_USEDEP}]
+		dev-python/treq[${PYTHON_USEDEP}]
+		dev-python/twisted[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/unpaddedbase64[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	test? ( $(python_gen_cond_dep '
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	') )
+"
+
+python_test() {
+	"${EPYTHON}" -m twisted.trial tests || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+	keepdir /var/{lib,log}/synapse /etc/synapse
+	fowners synapse:synapse /var/{lib,log}/synapse /etc/synapse
+	fperms 0750 /var/{lib,log}/synapse /etc/synapse
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+}
+
+pkg_postinst() {
+	optfeature "VoIP relaying on your homeserver with turn" net-im/coturn
+
+	einfo "In order to generate initial configuration run:"
+	einfo "sudo -u synapse synapse_homeserver \\"
+	einfo "    --server-name matrix.domain.tld \\"
+	einfo "    --config-path /etc/synapse/homeserver.yaml \\"
+	einfo "    --generate-config \\"
+	einfo "    --data-directory /var/lib/synapse \\"
+	einfo "    --report-stats=no"
+	einfo
+	einfo "See also upgrade notes:"
+	einfo "https://github.com/matrix-org/synapse/blob/develop/docs/upgrade.md"
+}