net-im/spectrum2: drop 2.1.3-r2

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 0 insertions, 112 deletions

diff --git a/net-im/spectrum2/Manifest b/net-im/spectrum2/Manifest
index 90a758c89a24..04897fd0b2ba 100644
--- a/net-im/spectrum2/Manifest
+++ b/net-im/spectrum2/Manifest
@@ -1,2 +1 @@
-DIST spectrum2-2.1.3.tar.gz 666005 BLAKE2B 8356b71506b5489780052eaf404a79f0f760fa3a8d35e80e30730c86b5e4acf21a1ac59fed46e472a1085dc29c6751f2c4e788ad60569bf15b48d198762f2a77 SHA512 b6bf39738998b56c8a90984446740c38547ffdaadaf280d3f4f29cb8a2e168898a7b010eff115394f473fd02c66f30ef383c4a542812d5abd03a87b064b446a8
 DIST spectrum2-2.2.0.tar.gz 666281 BLAKE2B aebf7d90a938ee62e5ae13955343a73c2f8a1484151519f59321b09d958cd49bd7b0914a3dc0a364d2469c691a653003bfc51324b69de38e3c59c9c248b3c672 SHA512 52125dd2b528b45cc814d4c62df6c0c431958dc5953af50731e765129e59a5dabdffd7f55d1709fe9854c81d6874d9549e8560f27b1b18a0af812299ef4c37ff
diff --git a/net-im/spectrum2/spectrum2-2.1.3-r2.ebuild b/net-im/spectrum2/spectrum2-2.1.3-r2.ebuild
deleted file mode 100644
index d3bff9c161d8..000000000000
--- a/net-im/spectrum2/spectrum2-2.1.3-r2.ebuild
+++ /dev/null
@@ -1,111 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake systemd tmpfiles
-
-DESCRIPTION="An open source instant messaging transport"
-HOMEPAGE="https://www.spectrum.im"
-SRC_URI="https://github.com/SpectrumIM/spectrum2/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64"
-IUSE="doc frotz irc mysql postgres purple sms +sqlite test twitter whatsapp xmpp"
-REQUIRED_USE="
-	|| ( mysql postgres sqlite )
-	test? ( irc )
-"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	acct-group/spectrum
-	acct-user/spectrum
-	dev-libs/boost:=[nls]
-	dev-libs/expat
-	dev-libs/libev:=
-	>=dev-libs/log4cxx-1.0.0:=
-	dev-libs/jsoncpp:=
-	dev-libs/openssl:=
-	dev-libs/popt
-	dev-libs/protobuf:=
-	net-dns/libidn:=
-	>=net-im/swift-4.0.2-r2:=
-	net-misc/curl
-	sys-libs/zlib:=
-	frotz? ( !games-engines/frotz )
-	irc? ( net-im/libcommuni )
-	mysql? (
-		|| (
-			dev-db/mariadb-connector-c
-			dev-db/mysql-connector-c
-		)
-	)
-	postgres? ( dev-libs/libpqxx:= )
-	purple? (
-		dev-libs/glib
-		net-im/pidgin:=
-	)
-	sms? ( app-mobilephone/smstools )
-	sqlite? ( dev-db/sqlite:3 )
-	twitter? ( net-misc/curl )
-	whatsapp? ( net-im/transwhat )"
-
-DEPEND="
-	${RDEPEND}
-	doc? ( app-doc/doxygen )
-	test? ( dev-util/cppunit )
-"
-
-PATCHES=( "${FILESDIR}/${PN}-2.1.3-log4cxx-1.0.0.patch" )
-
-src_prepare() {
-	# Respect users LDFLAGS
-	sed -i -e "s/-Wl,-export-dynamic/& ${LDFLAGS}/" spectrum/src/CMakeLists.txt || die
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DENABLE_DOCS="$(usex doc)"
-		-DENABLE_FROTZ="$(usex frotz)"
-		-DENABLE_IRC="$(usex irc)"
-		-DENABLE_MYSQL="$(usex mysql)"
-		-DENABLE_PQXX="$(usex postgres)"
-		-DENABLE_PURPLE="$(usex purple)"
-		$(usex irc '-DENABLE_QT4=OFF' '')
-		-DENABLE_SMSTOOLS3="$(usex sms)"
-		-DENABLE_SQLITE3="$(usex sqlite)"
-		-DENABLE_TESTS="$(usex test)"
-		-DENABLE_TWITTER="$(usex twitter)"
-		-DENABLE_XMPP="$(usex xmpp)"
-		-DLIB_INSTALL_DIR="$(get_libdir)"
-	)
-
-	cmake_src_configure
-}
-
-src_test() {
-	cd "${BUILD_DIR}/tests/libtransport" || die
-	./libtransport_test || die
-}
-
-src_install() {
-	cmake_src_install
-
-	diropts -o spectrum -g spectrum
-	keepdir /var/log/spectrum2 /var/lib/spectrum2
-	diropts
-
-	newinitd "${FILESDIR}"/spectrum2.initd spectrum2
-	systemd_newunit "${FILESDIR}"/spectrum2.service spectrum2.service
-	newtmpfiles "${FILESDIR}"/spectrum2.tmpfiles-r1 spectrum2.conf
-
-	einstalldocs
-}
-
-pkg_postinst() {
-	tmpfiles_process spectrum2.conf
-}