net-dns/pdns-recursor: Version bump to 4.4.5 and 4.5.5

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Sven Wegener <swegener@gentoo.org>

3 files changed, 172 insertions, 0 deletions

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index 1854e8c0747b..147ec7653f54 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1,3 +1,5 @@
 DIST pdns-recursor-4.4.4.tar.bz2 1399645 BLAKE2B 2ef2a59b9c402ab9d9b59d6b89e85b7103dbd9cdcc6147d08f09b85209cb2e298ff539dcb24895a4711f4e7c55c398d0307f237b22d1bdadaf01ec3925af0e8f SHA512 de8ac38d77a4700cd9dd64aad2ba7d1a97057683ace34f1dc3b2e9680faef5637ce7cedb66ceb0b7701f7ff6ef80cbee653549302805b30f9a6defa3a4e8e830
+DIST pdns-recursor-4.4.5.tar.bz2 1400394 BLAKE2B a373d15987860bd6b890e5aa5900f28623ff763a711e527b05c3de950c7fbec186dc5e085100008a8ee89bab24140b0f993357349ec04d968e7f386156cdefbc SHA512 21f4172bb8908cfb53e8d457533a85940b13da6733c2da3972b587e64a0f6d52bfd52b85d5d65769c33dd479ce89b6306bdd105c120ab99b32963e7f0cfbc2e2
 DIST pdns-recursor-4.5.2.tar.bz2 1464834 BLAKE2B 88acd7a6edecf8188b366a9fcff0eaf1b71429df8aad4dbcf157be39901b56ee3c9a9d55bf55bb060bcbb59f68b3ff8987788f4186a7122787874f895be1e751 SHA512 02a9f725c7528f91eb45409b32ffa06cb7fca1f0151907efcd8b75100942e98f593858543df15423413d69c9fd433bad3c8bad0a84f8144af07c637f22a86d5e
 DIST pdns-recursor-4.5.4.tar.bz2 1466655 BLAKE2B 35438eb8dc08990058924d4603e1f7fe2f74f8b2c61e96a82d6972a95f7b3cb43188fa10fa2dc70b699611057a21ba9f78eb3840976ce222c82ea32bdc374bb1 SHA512 403276ab06519a05154fca47fb7270d0199e770f1049a0503a0a1421f2d6fb7df6e9d5359d48348608d6b784e18ac815dd523051b7312f46ad4b510b608af7ab
+DIST pdns-recursor-4.5.5.tar.bz2 1472089 BLAKE2B 408bd0d11b0945de15fe22b290b127a9b7f9f053359a0269fb9e478ae536ed5c4b5ad3b5fa8b15d7786fdd0cdd8721d5a5cb66d46f816105e37ecd9fc9557854 SHA512 7df2e89eea55e870724370753b39d867e2b32fc8bcbdb3efaefa824917b16b9d382817dce7d551dc16d8ad0b0c04b3021cba310b47de969fe54c395eafe7706b
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.4.5.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.4.5.ebuild
new file mode 100644
index 000000000000..dc546d8cd6ca
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.4.5.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap protobuf snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}
+	dnstap? ( protobuf )"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	protobuf? (
+		dev-libs/protobuf
+		>=dev-libs/boost-1.42:=
+	)
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	dev-libs/openssl:=
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with protobuf) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.5.5.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.5.5.ebuild
new file mode 100644
index 000000000000..391869be2aec
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.5.5.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug dnstap snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	dev-libs/openssl:=
+	>=dev-libs/boost-1.35:="
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}